topic Re: Compress Spaces while using PUT STATEMENT in SAS Programming

Compress Spaces while using PUT STATEMENT

PRAVIN_JAIN — Tue, 11 Oct 2022 08:52:37 GMT

I am creating a text files from SAS dataset, I used BEST32. for numeric variables. But upon using this I get lot of spaces in field values in text file due to this file size is increasing a lot. How i can compess these spaces.

ex -

} 999999998 }} 110 } 237.877 }

Sample Code -

data _null_;
set ds_1;
file 'path' DSD lrecl=15000;
put FILE_CREATE_DT +(-1) "}" COUNTRY +(-1) "}" OPEN_DT +(-1) "}" OWN_NUM BEST32. +(+1) "}"
LIMIT BEST32. +(+1) "}" BAL BEST32. +(+1) "}" OWN_NAME;
run;

Re: Compress Spaces while using PUT STATEMENT

LinusH — Tue, 11 Oct 2022 09:32:32 GMT

First create a temporary variable with the whole string you wish to PUT.

While doing so, you can the various trimming functions SAS offers, like CATS, CATX, TRIM, TRIMN, COMPRESS, LEFT etc.

Re: Compress Spaces while using PUT STATEMENT

Ksharp — Tue, 11 Oct 2022 12:20:53 GMT

Do NOT adding the format, just remove them.

put LIMIT +(+1) "}" BAL +(+1) "}" OWN_NAME;

Re: Compress Spaces while using PUT STATEMENT

ballardw — Tue, 11 Oct 2022 15:41:41 GMT

Are attempting to create a specific file type such as JSON?

Re: Compress Spaces while using PUT STATEMENT

Tom — Tue, 11 Oct 2022 15:57:49 GMT

Use the : modifier to allow you to include a format specification in the PUT statement and yet still generate the result the same as if you used LIST MODE instead of FORMATTED mode.

put
 FILE_CREATE_DT +(-1) "}" 
 COUNTRY +(-1) "}" 
 OPEN_DT +(-1) "}" 
 OWN_NUM :BEST32. +(-1) "}"
 LIMIT :BEST32. +(-1) "}" 
 BAL :BEST32. +(-1) "}" 
 OWN_NAME
;

Or simply attach the format to the variable and remove the format specification from the PUT statement.

put
 FILE_CREATE_DT +(-1) "}" 
 COUNTRY +(-1) "}" 
 OPEN_DT +(-1) "}" 
 OWN_NUM  +(-1) "}"
 LIMIT  +(-1) "}" 
 BAL  +(-1) "}" 
 OWN_NAME
;
format OWN_NUM LIMIT BAL best32.;

Also since you seem to just want to generate '}' as the delimiter why not tell the FILE statement to do that?

data _null_;
  set ds_1;
  file 'path' DSD dlm='}' lrecl=15000;
  put FILE_CREATE_DT COUNTRY OPEN_DT OWN_NUM LIMIT BAL OWN_NAME;
  format OWN_NUM LIMIT BAL best32.;
run;