topic proc tabulate: removing table outlines and exporting to pdf in SAS Programming

proc tabulate: removing table outlines and exporting to pdf

Anita_n — Mon, 10 Oct 2022 08:10:58 GMT

Dear all,

I have being tring to remove the table outlines in proc tabulate without any success.

When I use the the FORMCHAR= option statement it works in the result viewer but in the pdf destination

this doesn't show. Please any help.

If possible, I will like to remove all row and column outlines or probably substitute this with short dashes maybe.

Here the code:

ods pdf file="mypath\test.pdf";
proc tabulate data=sashelp.cars format=6.0 style=[font_size=5pt just=c cellwidth=10 fontstyle=italic] formchar= '  ' noseps;
where make in ("Acura", "Audi", "BMW");
class make type origin / order=data style=[textalign=center ] missing;
  classlev make type origin/ style=[background=white font_weight=bold font_size=5pt foreground=dimgray cellpadding=0 ];
   var  MSRP /;
   table type*MSRP='' *sum='' ,
         make=''*origin='' / row=float nocontinued indent=3 rts=8  misstext=[label=" " ] style=[cellpadding=5]
         box=[label='Type ' style=[background=white foreground=dimgray font_weight=bold font_size=5pt ]];
run;

ods pdf close;

Thanks for any help

Re: proc tabulate: removing table outlines and exporting to pdf

Ksharp — Mon, 10 Oct 2022 11:35:11 GMT

ods pdf file="c:\temp\test.pdf" style=journal;
proc tabulate data=sashelp.cars format=6.0 style=[font_size=5pt just=c cellwidth=10 fontstyle=italic  bordertopcolor=white  borderbottomcolor=white] formchar= '  ' noseps;
where make in ("Acura", "Audi", "BMW");
class make type origin / order=data style=[textalign=center bordertopcolor=white  borderbottomcolor=white] missing;
  classlev make type origin/ style=[background=white font_weight=bold font_size=5pt foreground=dimgray cellpadding=0  bordertopcolor=white  borderbottomcolor=white];
   var  MSRP /;
   table type*MSRP='' *sum='' ,
         make=''*origin='' / row=float nocontinued indent=3 rts=8  misstext=[label=" " ] style=[cellpadding=5]
         box=[label='Type ' style=[background=white foreground=dimgray font_weight=bold font_size=5pt  bordertopcolor=white  borderbottomcolor=white]];
run;

ods pdf close;

Re: proc tabulate: removing table outlines and exporting to pdf

Anita_n — Mon, 10 Oct 2022 12:06:56 GMT

Is there also a way to use short dashes

Re: proc tabulate: removing table outlines and exporting to pdf

Ksharp — Mon, 10 Oct 2022 12:37:59 GMT

Sorry. I can't help you. Maybe @Cynthia_sas knew the solution.

style "BORDERBOTTOMSTYLE=" is only valid in Markup family, PowerPoint, Excel, RTF, and Measured RTF destinations,NOT pdf .

The following is from HTML:

ods pdf file="c:\temp\test.pdf" style=pearl;
proc tabulate data=sashelp.cars format=6.0 style=[font_size=5pt just=c cellwidth=10 fontstyle=italic   borderbottomstyle=dashed BORDERBOTTOMWIDTH=2] formchar= '  ' noseps;
where make in ("Acura", "Audi", "BMW");
class make type origin / order=data style=[textalign=center  borderbottomstyle=dashed  BORDERBOTTOMWIDTH=2] missing;
  classlev make type origin/ style=[background=white font_weight=bold font_size=5pt  cellpadding=0   borderbottomstyle=dashed  BORDERBOTTOMWIDTH=2];
   var  MSRP /;
   table type*MSRP='' *sum='' ,
         make=''*origin='' / row=float nocontinued indent=3 rts=8  misstext=[label=" " ] style=[cellpadding=5]
         box=[label='Type ' style=[background=white  font_weight=bold font_size=5pt   borderbottomstyle=dashed  BORDERBOTTOMWIDTH=2]];
run;

ods pdf close;

Re: proc tabulate: removing table outlines and exporting to pdf

Anita_n — Mon, 10 Oct 2022 13:17:24 GMT

Thankyou 🙂

Re: proc tabulate: removing table outlines and exporting to pdf

Cynthia_sas — Tue, 11 Oct 2022 23:22:45 GMT

Hi:

One way to remove all the lines without changing the borders is to use the RULES and FRAME attributes as style overrides on the TABLE statement, as shown below:

You asked later about having the lines made up of short dashes, that harkens back to old LISTING style output. If find the dashes as borders to be very distracting. However, if you need/want to do that, then you'll need to move into the world of style overrides for the border settings. You'll have to look in the documentation though, I am not sure that PDF will support a line style of dashes for the borders; although RTF might.

Cynthia

Re: proc tabulate: removing table outlines and exporting to pdf

Anita_n — Wed, 12 Oct 2022 11:11:25 GMT

@Cynthia_sas : thank you Cynthia