topic Re: Kaplan Meier Curve doesn't show top and bottom axis value in SAS Programming

Kaplan Meier Curve doesn't show top and bottom axis value

yechen — Sat, 08 Oct 2022 05:27:08 GMT

Dear all,

When I used proc lifetest to plot Kaplan-Meier curve and found the curve only showed between 0.25 and 0.75.

Besides, the Y-Axis automatically becomes "CIF" rather than "survival probability". (as the followed screenshot)

The code I test is very basic as followed:

PROC LIFETEST DATA=MYEL METHOD=KM;
TIME DUR*STATUS(0);
RUN;

I tried using other codes and dataset which performed normally before. I also tried copying the code and data from SAS tutorial directly. I even tried uninstalling and reinstalling the SAS program. But it continued to show this way.

If everyone used to face this problem, please let me know how to solve it. Thank you.

Re: Kaplan Meier Curve doesn't show top and bottom axis value

ballardw — Sat, 08 Oct 2022 07:47:42 GMT

What happens if you add this to your Proc Lifetest statement:

plots=survival(nocensor )

There is an entire section in the documentation on modifying and controlling these plots taking maybe 40 or 50 pages. Quite often there will be multiple ways to accomplish something.

You can start here for more ideas:

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.4/statug/statug_kaplan_toc.htm

Note: without your data we can't test code.

Instructions here: https://communities.sas.com/t5/SAS-Communities-Library/How-to-create-a-data-step-version-of-your-data-AKA-generate/ta-p/258712 will show how to turn an existing SAS data set into data step code that can be pasted into a forum code box using the <> icon or attached as text to show exactly what you have and that we can test code against.

Re: Kaplan Meier Curve doesn't show top and bottom axis value

yechen — Sat, 08 Oct 2022 16:00:24 GMT

Thank you for the repley. I used the code "plots=survival(nocensor )" you suggested. But the graph still only showed between 0.25 and 0.75. The followed are the graph and the codes I tested. I've tried some steps in the documents to force the graph show top limit to 1.0 but it doesn't work.

DATA MYEL;
	INPUT DUR STATUS TREAT RENAL;
	DATALINES;
8  1   1   1
180  1   2   0
632  1   2   0
852  0   1   0
52  1   1   1
2240  0   2   0
220  1   1   0
63  1   1   1
195  1   2   0
76  1   2   0
70  1   2   0
8  1   1   0
13  1   2   1
1990  0   2   0
1976  0   1   0
18  1   2   1
700  1   2   0
1296  0   1   0
1460  0   1   0
210  1   2   0
63  1   1   1
1328  0   1   0
1296  1   2   0
365  0   1   0
23  1   2   1
     ;
RUN;
*Kaplain-Merier Estimation;
PROC LIFETEST DATA=MYEL METHOD=KM plots=survival(nocensor );
	TIME DUR*STATUS(0);
RUN;

Re: Kaplan Meier Curve doesn't show top and bottom axis value

Reeza — Sat, 08 Oct 2022 19:50:49 GMT

Interestingly when I run the code you posted it shows the full axis.

I wonder if you modified the options earlier?

Here is how you can customize the axis:

filename demo temp;

data _null_;
   %let url = //support.sas.com/documentation/onlinedoc/stat/ex_code/142;
   infile "http:&url/templft.html" device=url;

   file demo;
   retain pre 0;
   input;
   _infile_ = tranwrd(_infile_, '&amp;', '&');
   _infile_ = tranwrd(_infile_, '&lt;' , '<');
   if index(_infile_, '</pre>') then pre = 0;
   if pre then put _infile_;
   if index(_infile_, '<pre>')  then pre = 1;
run;

%inc demo / nosource;

%ProvideSurvivalMacros;

%let yOptions = label="My Custom Label"
                linearopts=(viewmin=0 viewmax=1
                            tickvaluelist=(0 .1 .25 .5 .75 .9 1));

%CompileSurvivalTemplates;

*Kaplain-Merier Estimation;
PROC LIFETEST DATA=MYEL METHOD=KM plots=survival(nocensor );
	TIME DUR*STATUS(0);
RUN;

The first part downloads the macros from SAS that allow for easy customization and then you can set the options list.

Re: Kaplan Meier Curve doesn't show top and bottom axis value

yechen — Sun, 09 Oct 2022 03:17:37 GMT

Thank you. It works!!! I appreciate it.

I am not aware that I changed any options or setting.

But maybe I changed unintentionally when I tried coding before.

Re: Kaplan Meier Curve doesn't show top and bottom axis value

WarrenKuhfeld — Sun, 09 Oct 2022 10:22:18 GMT

Be sure to delete the modified templates when you are done to avoid having problems next time. The documentation shows you how.