topic Re: Is there a way to convert a macro variable with multiple values (in a long string) into multiple in SAS Programming

Is there a way to convert a macro variable with multiple values (in a long string) into multiple mac

StickyRoll — Fri, 07 Oct 2022 07:46:15 GMT

Is there a way to convert a macro variable with multiple values (in a long string) into multiple macro variables?

I have a macro variable as below.

%let carbrand = bmw ford lincoln honda toyota nissan;

I want to convert it to multiple macro variables as below.

Reading &carbrand. and create new macro variables:
car1=bmw
car2=ford
car3=lincoln
....
....
car6=nissan

all carN are macro variables

So, I can only think of assigning the long string of &carbrand. into a datastep, and by using scan function, assign it into multiple rows in a datastep. Then, using proc sql select into to assign it back to Macro Variables (carN). However, I am sure there is a simpler and faster function to perform that.

Seeking for further advice.

Re: Is there a way to convert a macro variable with multiple values (in a long string) into multiple

Astounding — Fri, 07 Oct 2022 09:46:44 GMT

Macro language supports that type of a loop. For example, inside a macro definition you could code:

%do n=1 %to 6;
%let car&n = %scan(&carbrand, &n);
%end;

There could be small issues along the way. For example you may need to add inside the loop:

%global car&n;

Re: Is there a way to convert a macro variable with multiple values (in a long string) into multiple

ballardw — Fri, 07 Oct 2022 15:50:34 GMT

One way:

%macro dummy;
%let carbrand = bmw ford lincoln honda toyota nissan;

%do i=1 %to %sysfunc(countw(&carbrand));
   %global car&i;
   %let car&i = %scan(&carbrand.,&i);
%end;

%mend;

%dummy;

If you have "words" that include a space you need to use a delimiter in your list and tell the COUNTW and %SCAN functions to use that delimiter.

I have a %global so the variables persist outside of this specific macro. If you need them outside of the macro I would suggest providing the result of count as well as a macro variable so it is available if needed.

Re: Is there a way to convert a macro variable with multiple values (in a long string) into multiple

Tom — Fri, 07 Oct 2022 18:01:38 GMT

There is usually no need to create so many macro variables.

Just use one macro variable to hold the current word from the list.

%let carbrand = bmw ford lincoln honda toyota nissan;
%do index=1 %to %sysfunc(countw(&carbrand,%str( )));
  %let car=%scan(&carbrand,&index,%str( ));
  %* code that uses &CAR for something ;
%end;