topic Re: how to extract differ order using substring fuction or other using other fuctions in SAS Programming

how to extract differ order using substring fuction or other using other fuctions

vallsas — Thu, 06 Oct 2022 10:42:03 GMT

hi,

i have 12.2.3.4

12.33.44.55

122.333.333.55

variable having data like above would like to extract first 3 parts. by using substring it is not possible is there any other functions in sas to get result like below

12.2.3

12.33.44

122.333.333

Re: how to extract differ order using substring fuction or other using other fuctions

Patrick — Thu, 06 Oct 2022 11:04:12 GMT

data have;
  infile datalines truncover;
  input string $20.;
  datalines;
12.2.3.4
12.33.44.55
122.333.333.55
12.2
;

data want;
  set have;
  if 0 then string_want=string;
  string_want=catx('.',scan(string,1,'.'),scan(string,2,'.'),scan(string,3,'.'));
run;

proc print data=want;
run;

Re: how to extract differ order using substring fuction or other using other fuctions

FreelanceReinh — Thu, 06 Oct 2022 11:14:06 GMT

Hi @vallsas,

@vallsas wrote:

... would like to extract first 3 parts. by using substring it is not possible ...

Why not?

data want;
input have :$30.;
want=substr(have,1,findc(have,'.','b')-1);
cards;
12.2.3.4
12.33.44.55
122.333.333.55
;

Or, if the number of "parts" varies:

data want(drop=pos len);
input have :$30.;
call scan(have,3,pos,len);
want=substr(have,1,pos+len-1);
cards;
12.2.3.4.5
12.33.44.55.66.77
122.333.333.55.6.77.888.9
;