topic Re: Set dummy variables in SAS Programming

Set dummy variables

greenie — Sun, 11 Sep 2022 17:21:17 GMT

hi I want to put age, height, BMI, race, and history of hormone therapy into my logistic regression model, how should I write the code?

age, height are numerical

BMI

1="0-18.5" 2="18.5-25" 3="25-30" 4="30+" 5=missing

race I set as:

NHW =(race = 1);

NHB =(race = 2);

hisp =(race = 3);

otherrace = (race = 4) and (race = 5) and (race= 6);

and I want NHW as reference.

hormone

.F="No Form" .G="Wrong Gender" .M="Not Answered" 0="No" 1="Yes" 2="Don't Know"

and I set hormone as dummy variables

hormone0 =(horm_f = 0);/*No*/

hormone1 =(horm_f = 1);/*Yes*/

So my codes for logistic regression:

proc logistic data = e.tmp;
where em_f in (0,1);
model emf (event = '1')= lm_cat age height BMI NHB hisp otherrace hormone0 hormone1/cl;
run;

But the results showed:

Note:

The following parameters have been set to 0, since the variables are a linear combination of other variables as shown

otherrace =

I don't know why. Can anyone help me?

Re: Set dummy variables

ballardw — Sun, 11 Sep 2022 18:12:54 GMT

With SAS you and Proc Logistic, indeed many regression procedures, you do not need to "set dummy variables". Categorical variables belong on a CLASS statement. SAS will create any internal dummies needed for calculations.

You would indicate which is the reference level you want on the CLASS statement.

The CLASS statement must come before the model statement.

For your "race" variable I would suggest creating a custom format and use that for creating a group like "otherrace"

proc format;
value myrace
1='NHW'
2='NHB'
3='Hisp'
4,5,6 = 'Other race'
;

Proc logistic data=e.tmp;
   where em_f in (0,1);
   class race (ref='NHW')
         horm_f
         bmi
   ;
   format race myrace. ;
   model emf (event = '1') = lm_cat age height race horm_f bmi /cl
   ;
run;

Variables on the Class statement, if you want to specify the reference level use the FORMATTED value in the (Ref= ) option.

Since I don't have your formats are data I can't test some possible problems in the code you posted.

Such as the above code assumes there is a variable named EM_F that is not the variable on the Model statement.

One might guess that your LM_CAT variable is also some sort of categorical variable. If so it also likely belongs on the CLASS statement.

The particular error you show I would expect to see if you actually had included the NHW variable you describe on the model statement.

The Otherrace is indeed dependent on the other "race" variables you created. The way you created them otherrace would be 1 only when all the others are 0, and 0 only when one of the others is a 1. So it is a linear combination of the other race variables.

Re: Set dummy variables

mkeintz — Sun, 11 Sep 2022 18:16:29 GMT

You have 4 race categories, but only 3 degrees of freedom among them. If you know the values of NWH, NWB, and HISP you automatically know the value for OTHERRACE - or more generally if you know three of the race dummies, you know what the fourth must be.

It appears that proc logistic is implicitly setting OTHERRACE as the reference condition, and all the race-variable beta's will be with respect to otherrace.

You could drop otherrace from the model specification, which should eliminate the note, but get the same parameter estimates.

But if you want NWH as the reference, drop it instead and keep the other three.

Re: Set dummy variables

greenie — Sun, 11 Sep 2022 18:38:45 GMT

Thank you. Yeah I want to set NHW as the ref. So I didn't include NHW in my model, but I keep other three there (NHB, hisp, Otherrace). I think SAS would take NHW as ref, but why it takes Otherrace as ref?

Re: Set dummy variables

mkeintz — Sun, 11 Sep 2022 19:59:39 GMT

@greenie wrote:

Thank you. Yeah I want to set NHW as the ref. So I didn't include NHW in my model, but I keep other three there (NHB, hisp, Otherrace). I think SAS would take NHW as ref, but why it takes Otherrace as ref?

I'm just guessing but I suppose that proc logistic takes the rightmost predictor listed as the reference when that predictor is a linear combination of predictors to its left.

This is the thing about SAS and many other computer programming tasks. The computer is always ready for you to experiment to answer such questions as this.

But frankly I think you might be better off using @ballardw's suggestion, because its syntax allows you to clearly specify the reference category, and also avoid SAS needing to notify you that you have a linear relationship among the 4 final categories.

My comments were more directed at WHY you got that note.

Re: Set dummy variables

FreelanceReinh — Sun, 11 Sep 2022 21:59:15 GMT

@greenie wrote:

otherrace = (race = 4) and (race = 5) and (race= 6);

If this is really how you coded otherrace, i.e., with ANDs rather than ORs, then this "predictor" is constantly zero. Which I think is what the log means by

Note:

The following parameters have been set to 0, since the variables are a linear combination of other variables as shown

otherrace =

0

(0 as a trivial "linear combination" of zero or more variables).

As @ballardw wrote, you should really use the CLASS statement for the categorical predictors. It was a great improvement of PROC LOGISTIC when this statement was introduced in SAS version 8.