topic Re: Removing special character from a string in SAS Programming

Removing special character from a string

stevenyan0127 — Wed, 07 Sep 2022 20:24:20 GMT

Hi, I'm having some problem removing special characters in my dataset.

For values ">10,000(3/29), how do I just extract "10,000" for those values?

I have tried :

initial_dimer=prxchange('s/\(([^\)]+)\)//i', -1, initial_dimer),

but it just removes the whole thing and leaves it blank.

Any help would be appreciated! Thanks!

Re: Removing special character from a string

mkeintz — Thu, 08 Sep 2022 13:49:53 GMT

If you just have two standard patterns, namely (where 9 represents any sequence of digits).

>99,999(xxxx)
and
999

then in the case of the first pattern you can scan for the 1st "word" starting at position 2, where "word" is a string that terminates at the separator "(". For the second pattern it's just a straight copy.

data have;
  input string $20.;
datalines;
>10,000(3/29)
256
run;

data want;
  set have;
  if string=: '>' then x=scan(substr(string,2),1,'(');
  else x=string;
  put (_all_) (=);
run;

Note the

=:

comparison operator compares two strings, truncating the longer string to the length of the shorter string. So the comparison tests whether the string starts with a ">".

Re: Removing special character from a string

Patrick — Thu, 08 Sep 2022 05:53:55 GMT

and here a regex that should work

data have;
  input string $20.;
datalines;
>10,000(3/29)
256
run;

data want;
  set have;
  string=prxchange('s/^[^\d]*(\d[\d,]*).*$/$1/i', -1, strip(string));
  put string=;
run;

Re: Removing special character from a string

Ksharp — Thu, 08 Sep 2022 11:10:05 GMT

data have;
  input string $20.;
want=scan(string,1,',.','kd');
datalines;
>10,000(3/29)
256
;
run;