topic Re: How to Include Zero to %Do macro loop in SAS Programming

How to Include Zero to %Do macro loop

MrTAL — Wed, 31 Aug 2022 06:25:58 GMT

Hi.. I'm relatively new and I'm Trying to extract 60 months data from source tables which names as DATA_YYYYMM and created separate data tables.

I wrote the below macro for this.

%MACRO DO_YRMN;

%do YY = 2015 %to 2020;
%do MM = 01 %to 12;


DATA My_DATA_TABLE&YY.&MM
/**** my VAR*****/
SET SOURCE_TABLE&YY.&MM;
RUN;


%END;
%END;
%MEND DO_YRMN;
%DO_YRMN;

Macro runs fine. But the issue is zero is not used. So SAS created code as YYYYM only (20191) instead of YYYYMM(201901)

Re: How to Include Zero to %Do macro loop

japelin — Wed, 31 Aug 2022 06:45:54 GMT

how about this code.

%do MM = 01 %to 12;
%if &MM<10 %then %let MM=0&MM.; /* Add this line */

Re: How to Include Zero to %Do macro loop

Kurt_Bremser — Wed, 31 Aug 2022 09:19:25 GMT

Or do this:

%do mm = 1 %to 12;
  %let mm = %sysfunc(putn(&mm.,z2.));

Re: How to Include Zero to %Do macro loop

MrTAL — Wed, 31 Aug 2022 12:29:15 GMT

Thanks.. it worked..

Re: How to Include Zero to %Do macro loop

MrTAL — Wed, 31 Aug 2022 12:30:07 GMT

Thank you so much.. this works tooo.. both the solutions are working.. 🙂

Re: How to Include Zero to %Do macro loop

Tom — Wed, 31 Aug 2022 13:20:39 GMT

Since you appear to be looping over months it is probably better to use actual dates instead.

%MACRO DO_YRMN;
%local start end offset yymm ;
%let start='01JAN2015'd ;
%let end='01DEC2020'd;
%do offset=0 %to %sysfunc(intck(month,&start,&end));
  %let yymm = %sysfunc(intnx(month,&start,&offset),yymmn6.);

DATA My_DATA_TABLE&YYMM
/**** my VAR*****/
SET SOURCE_TABLE&YYMM;
RUN;
%end;

%MEND DO_YRMN;
%DO_YRMN;

Now you can use intervals that are not complete years.

Re: How to Include Zero to %Do macro loop

MrTAL — Thu, 01 Sep 2022 10:25:05 GMT

Wow.. that's great.. Thank you so much for the knowledge share.. 🙂