topic Re: Simplify the Proc Freq Coding? in SAS Programming

Simplify the Proc Freq Coding?

ybz12003 — Fri, 26 Aug 2022 12:59:38 GMT

Hello,

Is there a way to simplify the Proc Freq coding below? I have extra 8 variables similar to sex and age. If I do one single step each, I have to do 16 steps to get the results.

proc freq data=Have;
	table  Gender * RSV / chisq nopercent nocol  out=Dataout_sex1;
	where RSV in (1,2);
	format RSV RSV. Gender Gender. ;
run;

proc freq data=Have;
	table  Gender * RSV / chisq nopercent nocol  out=Dataout_sex2;
	where RSV in (3,4);
	format RSV RSV. Gender Gender. ;
run;

proc freq data=Have;
	table  Age * RSV / chisq nopercent nocol  out=Dataout_age1;
	where RSV in (1,2);
	format RSV RSV. Age Age. ;
run;

proc freq data=Have;
	table  Age * RSV / chisq nopercent nocol  out=Dataout_age2;
	where RSV in (3,4);
	format RSV RSV. Age Age. ;
run;

Re: Simplify the Proc Freq Coding?

data_null__ — Fri, 26 Aug 2022 13:25:16 GMT

Show sample data in form of data step. What output are you interested in freqs chisq etc. Show example.

Re: Simplify the Proc Freq Coding?

AMSAS — Fri, 26 Aug 2022 13:39:53 GMT

The question is - What is your definition of simple. What you have already is simple just repetative.

Now if you want to automatically generate the repetative code you could do something like this:


/* Creae a macro with a single named parameter (multiWhere) */
/* multiWhere expects a list of where conditions seperated by a "/" */
%macro simple(multiWhere=) ;
	/* The %put statements are for debugging/seeing what happens */
	%put &=multiWhere ;
	/* create a counter (n) */
	%let n=1 ;
	/* scan multiWhere for the nth word using / as a seperator */
	%let where=%scan(&multiWhere,&n,"/") ;
	%put &=n &=where ;
	/* Repeat this step while &where has a value */
	%do %while(&where ne ) ;
		
		/* You code goes here */
		proc freq data=sashelp.class ;
		    /* Note the Dataout_sex&n the &n will be replaced by the value of the counter (&n) */
			table  sex * age / out=Dataout_sex&n;
			where sex in ("&where");
		run;

		/* Time to move onto the next Where clause */
		/* Increment the counter */
		%let n=%eval(&n+1) ;
		/* Get the next where clause */
		%let where=%scan(&multiWhere,&n,"/") ;
		%put &=n &=where ;
	%end ;

%mend  ;

/* Call the simple macro, passing a list of where clauses */
%simple(multiWhere=M/F) ;

Re: Simplify the Proc Freq Coding?

ChrisHemedinger — Fri, 26 Aug 2022 14:18:08 GMT

From the example you shared it looks like you have a 3rd category: if RSV is (1,2) vs RSV is (3.,4). If you make a dummy variable with that flag, perhaps you could then use PROC FREQ for an n-way analysis.

Re: Simplify the Proc Freq Coding?

ballardw — Fri, 26 Aug 2022 15:47:07 GMT

ODS output will allow you to place the results of multiple tables into a single data set.

You can use ( ) to group variables to create multiple tables in the tables statement: tables (a b c) * x creates tables a*x b*x and c*x.

Combine the two:

ods output crosstabfreqs=dataout1;
proc freq data=Have;
	table ( Gender age ) * RSV / chisq nopercent nocol;
	where RSV in (1,2);
	format RSV RSV. Gender Gender. ;
run;

Place the other variables in the ( ) with gender and age.

Not sure why you are filtering on RSV, so you still need to do two output sets. Note that the output data set may require some additional work to print "pretty" reports. There will be a variable that indicates which table a row of data comes from.

If you want a "pretty" output of counts you may want to consider a different procedure such as Proc Tabulate

proc tabulate data=have;
  class gender age <other variables go here>/missing;
  class rsv;
  tables gender age <other variables>,
         rsv*n
  ;
run;

which will show the first row of variables, gender age etc as column on the left with each variable values, and column of RSV counts for each cell.

The formatted values of the variables will be used to create the row/column headings if you add them to the code.

Re: Simplify the Proc Freq Coding?

ybz12003 — Fri, 26 Aug 2022 16:51:13 GMT

No need to