topic Macro variable was not created in SAS Programming

Macro variable was not created

Ronein — Thu, 25 Aug 2022 06:00:20 GMT

Hello

In this code I get warning and macro variable FromDate was not created.

May anyone help to solve the problem?

data ttt;
format date date9.;
input date : date9.;
cards;
12JAN2022
17SEP2020
13MAR2020
;
run;


%MACRO  Start_Date;
%if %sysfunc(exist(ttt)) %then %do;
proc sql noprint;
select max(date)+1 as FromDate into : FromDate
from ttt
;
quit;
%end;
%else %Do;
Data _null_;
call symput('FromDate','01SEP2020'd);
Run;
%end;
%Mend Start_Date;
%Start_Date;
%put &FromDate;
/*WARNING: Apparent symbolic reference FROMDATE not resolved.*/

Re: Macro variable was not created

Kurt_Bremser — Thu, 25 Aug 2022 06:08:28 GMT

Your macro variable is local to the macro, so you won't see it outside. And in case the dataset exists but is empty, it will also not be created.

Use your %IF in open code, without a macro definition:

%let fromdate = '01sep2020'd;
%if %sysfunc(exist(ttt)) %then %do;
proc sql noprint;
select max(date)+1  into : FromDate
from ttt
;
quit;
%end;

This takes care of both issues.

Re: Macro variable was not created

japelin — Thu, 25 Aug 2022 07:48:53 GMT

submit %global before submit macro or first in macro.

%global fromdate;
%Start_Date;

%MACRO  Start_Date;
%global fromdate;
%if %sysfunc(exist(ttt)) %then %do;
...