topic Re: Plotting 4 Ys in SAS Programming

How to 2X2 Chart ?!

hellohere — Sun, 17 Jul 2022 10:57:07 GMT

Say there is dataset contains X and 4Ys(Y1, Y2,Y3, and Y4).

How to generate a chart with 4-sub-charts (Y1~X, Y2~X, Y3~X and Y4~X)?!

Re: How to 2X2 Chart ?!

PaigeMiller — Sun, 17 Jul 2022 11:05:06 GMT

Explain in more detail. Show us a sample of the input data. Show us a mocked up version of the desired output.

Re: How to 2X2 Chart ?!

hellohere — Sun, 17 Jul 2022 12:33:37 GMT

One X with 4 Ys. One way is to plot 4Ys(below) with X within one chart.

When 4 Ys' Range varies and plot together does not make sense,

I like to make one chart with 4 carpets, each charting one Y with the same X

(SAS generate one Picture)

data temp;
do x=1 to 20;
y1=ranuni(1);y2=ranuni(2);y3=ranuni(3);y4=ranuni(4);
output;
end;
run;quit;

symbol1 interpol=join;symbol2 interpol=join;symbol3 interpol=join;symbol4 interpol=join;
proc gplot data=temp;
plot (y1 y2 y3 y4)*x/legend overlay;
run;quit;

Re: Plotting 4 Ys

PaigeMiller — Sun, 17 Jul 2022 12:46:32 GMT

First, your subject line is very misleading, there is no 2x2 charting in your question, and this confused me greatly. I suggest you go back to your original post and change it so that it has a more meaningful subject line.

Next, you provide data that really doesn't illustrate the problem. There's no different range of these 4 Y variables and they all fit nicely on one plot with one y-axis. As a recommendation to you, it is very helpful to provide data that illustrates your problem. It's never a good idea to make us guess.

Nevertheless at the risk of guessing wrong, here's some data that maybe closer to what you described, and a potential plot that might look better — but again, I am requesting that you tell us what you want instead of making us guess. Be specific, be detailed, be clear.

data temp;
do x=1 to 20;
y1=ranuni(1);
y2=10*ranuni(2);
y3=100*ranuni(3);
y4=1000*ranuni(4);
output;
end;
run;

proc sgplot data=temp;
series x=x y=y1;
series x=x y=y2;
series x=x y=y3;
series x=x y=y4;
yaxis type=log logstyle=logexpand logbase=10;
run;

Re: Plotting 4 Ys

hellohere — Sun, 17 Jul 2022 13:40:50 GMT

What wanted is stich the 4 plots into one(one pic/jpg), so that 4 takes four corners with the

final chart(top_left, top_right, bottom_left and bottom_right).

proc gplot data=sashelp.applianc(where=(cycle<=20));
plot units_1*cycle/legend overlay;
run;quit;
proc gplot data=sashelp.applianc(where=(cycle<=20));
plot units_2*cycle/legend overlay;
run;quit;
proc gplot data=sashelp.applianc(where=(cycle<=20));
plot units_3*cycle/legend overlay;
run;quit;
proc gplot data=sashelp.applianc(where=(cycle<=20));
plot units_4*cycle/legend overlay;
run;quit;

Re: Plotting 4 Ys

PaigeMiller — Sun, 17 Jul 2022 14:06:03 GMT

ods layout gridded columns=2 rows=2 advance=proc;
proc sgplot data=sashelp.applianc(where=(cycle<=20));
scatter y=units_1 x=cycle;
run;
proc sgplot data=sashelp.applianc(where=(cycle<=20));
scatter y=units_2 x=cycle;
run;
proc sgplot data=sashelp.applianc(where=(cycle<=20));
scatter y=units_3 x=cycle;
run;
proc sgplot data=sashelp.applianc(where=(cycle<=20));
scatter y=units_4 x=cycle;
run;
ods layout end;

Re: How to 2X2 Chart ?!

Ksharp — Mon, 18 Jul 2022 12:50:45 GMT

data temp;
do x=1 to 20;
y1=ranuni(1);
y2=10*ranuni(2);
y3=100*ranuni(3);
y4=1000*ranuni(4);
output;
end;
run;

proc sgscatter data=temp;
plot (y1-y4)*x;
run;

Re: How to 2X2 Chart ?!

hellohere — Thu, 21 Jul 2022 20:09:49 GMT

This is the one, one picture. Thanks,

Re: Plotting 4 Ys

hellohere — Wed, 24 Aug 2022 13:36:00 GMT

any way to enforce the size of the outcome picture?! THX
See, stitch this way, 4 picture together, you still need scroll down-up-left-right to see all details.
If just fit the SAS OUTPUR window and no need to scroll, that would be perfect.

Re: Plotting 4 Ys

PaigeMiller — Wed, 24 Aug 2022 14:16:05 GMT

ods graphics/height=3in width=4in;

You can play with the width and height to find the numbers that look best in your situation.

Re: Plotting 4 Ys

hellohere — Wed, 24 Aug 2022 14:45:31 GMT

Thanks, It almost saved my day. BUT I tried below with varied inch #, the outcome picture
is same size... any help?

data temp;
do x=1 to 20;
y1=ranuni(1);
y2=10*ranuni(2);
y3=100*ranuni(3);
y4=1000*ranuni(4);
output;
end;
run;

ods layout gridded columns=2 rows=2 advance=proc;
ods graphics/height=1in width=2in;
proc gplot data=temp; plot y1*x; run;
proc gplot data=temp; plot y2*x; run;
proc gplot data=temp; plot y3*x; run;
proc gplot data=temp; plot y4*x; run;
ods layout end;

Re: Plotting 4 Ys

PaigeMiller — Wed, 24 Aug 2022 15:08:47 GMT

You need to use PROC SGPLOT and the proper syntax in the SCATTER or SERIES command.

This will not work with PROC GPLOT.

Re: Plotting 4 Ys

ballardw — Wed, 24 Aug 2022 15:29:57 GMT

@PaigeMiller wrote:

You need to use PROC SGPLOT and the proper syntax in the SCATTER or SERIES command.

This will not work with PROC GPLOT.

At least not without the headaches of Proc Template to create the display template and Proc GREPLAY to associate each already create plot with a designated space in the template.

Re: Plotting 4 Ys

PaigeMiller — Wed, 24 Aug 2022 15:33:10 GMT

PROC TEMPLATE + PROC GREPLAY is needed to replace ODS LAYOUT GRIDDED. I don't think that was clear from what you wrote.

The simplicity of ODS LAYOUT GRIDDED seems to win hands down here.

Re: How to 2X2 Chart ?!

ballardw — Wed, 24 Aug 2022 15:38:46 GMT

Another approach may be to not create multiple variables to plot but add an indicator variable as to source/purpose/whatever and use SGPANEL to create one graph panel for each value of the Panelby variable(s).

data temp;
do x=1 to 20;
y1=ranuni(1);
y2=10*ranuni(2);
y3=100*ranuni(3);
y4=1000*ranuni(4);
output;
end;
run;

data toplot;
   set temp;
   array ys(*) y:;
   do i=1 to dim(ys);
      var=vname(ys[i]);
      value=ys[i];
      output;
   end;
   keep x var value;
run;

proc sgpanel data=toplot;
   panelby var /columns=2 rows=2 
                onepanel uniscale=column
   ;
   scatter x=x y=value;
run;

Or SGPLOT and group to overlay

proc sgplot data=toplot;
   ;
   scatter x=x y=value/group=var;
run;

Re: Plotting 4 Ys

hellohere — Wed, 07 Sep 2022 02:41:35 GMT

Any way to save the picture with specified filename and file location, such as c:\mypic\_pic_today_01.jpg/png ?! Thanks,