How to use a format that is craeated locally, but would like to use that same format on a SAS-server

Bjorta67 — Fri, 12 Aug 2022 12:14:28 GMT

/*===========================================================================
--Definiera libname på klienten
============================================================================*/
libname Data 'H:\Mina dokument\Arbete\SAS\Data';
/*===========================================================================
--Börja sända kod till servern
============================================================================*/
signon sasapp1;
libname r_work slibref=work server=sasapp1;
rsubmit;
/*===========================================================================
--Koppla upp mot databas
============================================================================*/
libname befpak odbc schema=dbo bulkload=yes
noprompt="driver=ODBC Driver 17 for SQL Server;
server=db100.prod.sql;
database=befpak;
Trusted_Connection=Yes";
/*===========================================================================
--Hämta data
============================================================================*/
data work.grunddata (keep=lan kommun fastbet kon alderslut civil);
set befpak.RTB202101_vy;
where alderslut >= 20;
run;
/*==========================================================================
--Sortera data
==========================================================================*/
proc sort data=work.grunddata;
by kommun;
run;
/*===========================================================================
--Skapa upp format ålder i 5-årsklasser
============================================================================*/
proc format;
value fmtAld5kl
0-4='0-4 år'
5-9='5-9 år'
10-14='10-14 år'
15-19='15-19 år'
20-24='20-24 år'
25-29='25-29 år'
30-34='30-34 år'
35-39='35-39 år'
40-44='40-44 år'
45-49='45-49 år'
50-54='50-54 år'
55-59='55-59 år'
60-64='60-64 år'
65-69='65-69 år'
70-74='70-74 år'
75-79='70-79 år'
80-84='80-84 år'
85-89='85-89 år'
90-94='90-94 år'
95-high='95-W år';
quit;
/*===========================================================================
--Aggregera
============================================================================*/
proc freq data=work.grunddata;
by kommun;
tables kon*civil*alderslut / out=work.tab_B1_A;
format alderslut fmtAld5kl.;
run;
/*===========================================================================
--Ladda ned resultattabellen till lokal maskin
============================================================================*/
proc download data=work.tab_B1_A
out=data.tab_B1_A;
run;
/*===========================================================================
--Sluta sända kod till servern
============================================================================*/
endrsubmit;
/*===========================================================================
--Lista 100 rader från tabellen
============================================================================*/
*proc print data=work.tab_B1_A(obs=100);
*run;
*proc print data=data.tab_B1_A(obs=100);
*run;
/*==========================================================================
Skapa utdata med valfritt format dvs kommasep/tabsep/excel
==========================================================================*/
proc export data=data.tab_B1_A
outfile='H:\Mina dokument\Arbete\SAS\Data\tab_B1_AX.txt'
dbms=CSV replace;
/* dbms="EXCEL" replace; */
/* dbms=TAB replace; */
run;
proc export data=data.tab_B1_A
outfile='H:\Mina dokument\Arbete\SAS\Data\tab_B1_AX.xlsx'
dbms=EXCEL label replace;
/* dbms=CSV replace;
dbms=TAB replace; */
run;

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Kurt_Bremser — Fri, 12 Aug 2022 12:56:18 GMT

Your PROC FORMAT is part of the RSUBMIT, so the format is created in the remote session.

Rerun the FORMAT code in your local session (after the ENDRSUBMIT) before exporting.

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Patrick — Sat, 13 Aug 2022 04:11:47 GMT

Given that you're already using RLS in your code with libref r_work the only thing you need to do is to add this libref to your local format search path FMTSEARCH.

options autosignon sascmd="!sascmd";

rsubmit sasapp1 connectpersist=yes;
  proc format;
    value $gender 'M'='Male' 'F'='Female';
  run;
endrsubmit;

libname r_work slibref=work server=sasapp1;
options append=(FMTSEARCH=r_work);
proc print data=sashelp.class;
  format sex $gender.;
run;

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Bjorta67 — Mon, 15 Aug 2022 08:07:30 GMT

Hi Patrik,
Thank you 😉
Kind regards
Björn

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Patrick — Mon, 15 Aug 2022 10:12:34 GMT

@Bjorta67 If that's what you were after please mark the answer as solution - else let us know what's still missing/not working for you.

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Bjorta67 — Mon, 15 Aug 2022 10:23:25 GMT

Yeahm, that works, thank you!

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Bjorta67 — Mon, 15 Aug 2022 10:25:00 GMT

Yeah, that works, thank you!

topic Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se in SAS Programming

How to use a format that is craeated locally, but would like to use that same format on a SAS-server

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se

Re: How to use a format that is craeated locally, but would like to use that same format on a SAS-se