topic Jump Out of SAS Dataset in SAS Programming

Jump Out of SAS Dataset

zsmith115 — Thu, 11 Aug 2022 15:57:41 GMT

Is there a way to jump out of a SAS dataset if a condition is met? For example, if I want to include an IF statement at the top of my code to determine if a condition is met, I want to jump over all code to the end of the program so none of the remaining code is executed. I've looked at the GOTO statement but the label where the code jumps to has to be within the same data statement which isn't what I need it to do. Below is a simplified example of the code:

data one;

set two;

If &have_file = 'No' then GOTO endhere;

run;

*******;

additional code that I want to skip if &have_file = 'No';

******;

endhere:;

run;

Any help would be appreciated.

Re: Jump Out of SAS Dataset

Quentin — Thu, 11 Aug 2022 16:03:02 GMT

You definitely can't jump out of a DATA step to a location outside of the DATA step.

You might want to look into the macro language, which can be used for conditional execution of SAS code.

In a data step, you can conditionally end the data step early. So you could set a macro variable SkipCode=1 and end the data step early.

Then in the macro language you could have your skippable code inside of a %if &skipcode ne 1 %then %do block. Or the macro language has a %GOTO statement which is another option.

Re: Jump Out of SAS Dataset

ballardw — Thu, 11 Aug 2022 16:15:01 GMT

Is the value of &have_file the name of a variable in the data set? If not then the IF is not useful and probably the wrong If. If you are setting the macro variable to avoid executing the data set because of an external to the data set condition then the structure would be MACRO code

%if &have_file=NO %then %goto Skipit;
   data one;
       set two;
   end;

%Skipit:

HOWEVER the %goto is only allowed in Macro definition code. Which means defining some of the code involved in a %macro / %mend block, likely with parameters to pass into the macro such as the value of your &have_file macro variable. The calling the compiled macro after the definition. Which depending on everything you are may be doing could be a bit of work.

Re: Jump Out of SAS Dataset

Tom — Thu, 11 Aug 2022 16:22:52 GMT

RETURN will end the current iteration of the data step and start the next iteration. If you don't want the implied OUTPUT at the end of the data step to run then use the DELETE statement instead.

STOP will end the data step immediately instead of waiting for the normal data step end. Note that most data steps actually end when they read past the end of the inputs in either the SET/MERGE/UPDATE statement or the INPUT statement.

Re: Jump Out of SAS Dataset

Tom — Thu, 11 Aug 2022 20:43:39 GMT

If you want to conditionally execute code you need to use MACRO statements.

You could use the first data step to set a macro variable than you can then use in the macro code.

For example if the trigger is that there are any observations in TWO where the value of X is larger than 5 you might do something like this:

%let any_found=0;
data _null_;
  set two;
  where x > 5 ;
  call symputx('any_found','1');
  stop;
run;

%if (&any_found) %then %do;
* other data steps and proc steps;
%end;

* end of program;

Re: Jump Out of SAS Dataset

mbuchecker — Thu, 11 Aug 2022 21:42:56 GMT

If you there is absolutely no other code after your "endhere", in other words you simply want the whole program to stop, code: if &have_file='No' then abort return;

otherwise use the macro %IF suggestion that others wrote.

Re: Jump Out of SAS Dataset

SASKiwi — Thu, 11 Aug 2022 22:06:45 GMT

What is the real condition you are testing for? If it whether a certain data file exists or not, pretty much any computer task scheduler can do that within the tool so you don't need to code for it in SAS at all. It does mean that you will have to run your SAS job in batch mode though.

Re: Jump Out of SAS Dataset

Patrick — Fri, 12 Aug 2022 10:30:55 GMT

One way to go if you're using a recent version of SAS9

%if %upcase(&have_file) ne NO %then
  %do;

    data one;
      set two;
    run;

    /*******
    additional code that I want to skip if &have_file = 'No';
    ******/

  %end;

Re: Jump Out of SAS Dataset

zsmith115 — Fri, 12 Aug 2022 12:04:38 GMT

Thanks to everyone that replied with suggestions. I was able to get my code to work using the %if %then %do logic.