topic Re: Proc tabulate-2 class vars and 1 measurement var in SAS Programming

Proc tabulate-2 class vars and 1 measurement var

Ronein — Tue, 09 Aug 2022 08:08:34 GMT

Hello,

I want to perform proc tabulate with 2 class variables and 1 measurement variable.

I want to modify the report and get the following:

What is the way to do it please?

data have;
input team $ position $ points;
cards;
A Guard 15
A Guard 12
A Guard 29
A Forward 13
A Forward 9
A Forward 16
B Guard 25
B Guard 20
C Guard 34
C Forward 19
C Forward 3
C Forward 8
;
run;

Title 'Distribution-N/SUM of points';
proc tabulate data=have;
class team position;
var points;
table team='' All, position * points='' * (N SUM) /misstext='0' box='Team';
run;

Re: Proc tabulate-2 class vars and 1 measurement var

Ksharp — Tue, 09 Aug 2022 12:27:31 GMT

data have;
input team $ position $ points;
p='position';
cards;
A Guard 15
A Guard 12
A Guard 29
A Forward 13
A Forward 9
A Forward 16
B Guard 25
B Guard 20
C Guard 34
C Forward 19
C Forward 3
C Forward 8
;
run;

Title 'Distribution-N/SUM of points';
proc tabulate data=have;
class team p position;
var points;
table team='' All, p=''*(
(position='' all)* N 
(position='' all)*points=''*SUM 
)/misstext='0' box='Team';
run;

Re: Proc tabulate-2 class vars and 1 measurement var

Astounding — Tue, 09 Aug 2022 12:54:35 GMT

@Ronein, good job describing the problem and your attempts to solve it.

@Ksharp, good solution, but I think you can get by without creating a new variable (but by shuffling pieces of the TABLE statement).

You have:

proc tabulate data=have;
class team p position;
var points;
table team='' All, p=''*(
(position='' all)* N 
(position='' all)*points=''*SUM 
)/misstext='0' box='Team';
run;

Try it this way:

proc tabulate data=have;
class team position;
var points;
table team='' All, points='Points by Position' * (
(position='' all)* N 
(position='' all)*SUM 
)/misstext='0' box='Team';
run;

I left the longer label in place for POINTS, rather than trying to explain it. But it can easily be shortened.

Re: Proc tabulate-2 class vars and 1 measurement var

Ronein — Tue, 09 Aug 2022 13:22:55 GMT

Thanks
May you please explain what is the meaning of p? As i see it is a new variable that you defined?

Re: Proc tabulate-2 class vars and 1 measurement var

Ksharp — Tue, 09 Aug 2022 13:35:57 GMT

p has value 'position' for all the obs, It is a dummy variable to make the top header 'position'.