topic Converting list to dataset column in SAS Programming

Converting list to dataset column

Jedrek369 — Thu, 28 Jul 2022 16:21:15 GMT

I have a list of values separated by space.

%let list = A B C;

I would like to create a single-column dataset.

Col1

Thanks in advance!

Re: Converting list to dataset column

Kurt_Bremser — Thu, 28 Jul 2022 16:45:57 GMT

data want;
do i = 1 to countw("&list.");
  col1 = scan("&list.",i);
  output;
end;
drop i;
run;

Re: Converting list to dataset column

ballardw — Thu, 28 Jul 2022 18:46:35 GMT

You may want to consider specifying a length for Col1 variable based on your knowledge of the starting list. The default length using @Kurt_Bremser's solution will create a variable that is the length of the entire list. If you have many values that could mean that you have a variable of several hundred (or thousand) characters even though the longest value of interest is only one or two or some other number much smaller than thousands.

Re: Converting list to dataset column

FreelanceReinh — Fri, 29 Jul 2022 09:38:10 GMT

You can also let SAS determine the minimum required length of Col1:

data wide / view=wide;
retain c1-c%sysfunc(countw(&list,%str( )))
       ("%sysfunc(tranwrd(&list,%str( ),%str(" ")))");
run;

proc transpose data=wide out=want(drop=_:);
var c:;
run;