topic Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC) in SAS Programming

Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 17:40:38 GMT

Suppose I want to use UNICODE characters in PROC SGPLOT. Can it be done?? My initial attempts to do so failed.

Example: Unicode 2265 (greater than or equal to) shows up properly in PROC PRINT

ods escapechar='~';
proc format;
    value weightf 0-59='<60'  60-high='~{unicode 2265}60';
run;
proc print data=sashelp.class;
    id name;
    var weight;
    format weight weightf.;
run;

but now PROC SGPLOT doesn't show the greater than or equal to sign. Can it be done? If so, how?

proc sgplot data=sashelp.class;
    vbar weight/response=height;
    format weight weightf.;
run;

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

pink_poodle — Mon, 18 Jul 2022 17:44:49 GMT

This will work if instead of formatting existing variable you create a new categorical variable with values "<60" and ">=60".

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 17:54:04 GMT

@pink_poodle wrote:
This will work if instead of formatting existing variable you create a new categorical variable with values "<60" and ">=60".

Not seeing it, still not working, unless I'm still doing something wrong.

ods escapechar='~';
proc format;
    value weightf 0-59='<60'  60-high='~{unicode 2265}60';
run;
data class;
    set sashelp.class;
    weight1=vvalue(weight);
    format weight weightf.; 
run;
proc sgplot data=class;
    vbar weight1/response=height;
run;

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

RichardDeVen — Mon, 18 Jul 2022 18:05:38 GMT

You can run SAS (Unicode Support) using icon or startup option

-CONFIG "C:\Program Files\SASHome\SASFoundation\9.4\nls\u8\sasv9.cfg"

In your code paste the special symbol (≥) directly. SGPLOT will honor the special character in the source code.

ods graphics / width=300px;

proc format;
    value weightf 0-59='< 60'  60-high='≥ 60';    
run;
proc print data=sashelp.class;
    id name;
    var weight;
    format weight weightf.;
run;
proc sgplot data=sashelp.class;
    vbar weight / response=height;
    format weight weightf.;
run;

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 18:08:49 GMT

@RichardDeVen wrote:

You can run SAS (Unicode Support) using icon or startup option
-CONFIG "C:\Program Files\SASHome\SASFoundation\9.4\nls\u8\sasv9.cfg"

Please explain what this means.

In your code paste the special symbol (≥) directly.

Please explain how to do this. (And please explain how to do this with other unicode characters that I might want to use some day).

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

pink_poodle — Mon, 18 Jul 2022 18:14:30 GMT

data cat;
     set sashelp.class;
     if weight >= 60 then wcat = ">=60";
     else if not missing(weight) and weight < 60 then wcat = "<60";
run;

proc sgplot data=cat;
    vbar wcat / response=height;
run;

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 18:14:19 GMT

if weight >= 60 then wcat = '>=60';

This is not what I wanted. I want one character which is the greater than or equal symbol; it is not the two characters you typed.

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

FreelanceReinh — Mon, 18 Jul 2022 18:28:56 GMT

Hello Paige,

For me it works if I use the "(*ESC*)" notation instead of the ODS ESCAPECHAR in the PROC FORMAT step

value weightf 0-59='<60'  60-high="(*ESC*){Unicode '2265'x}60";

(as @Ksharp did three days ago in another thread -- credit to him).

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

RichardDeVen — Mon, 18 Jul 2022 18:31:18 GMT

In Windows 10 in the Start menu scroll down to the S group open the SAS folder and see the SAS 9.4 (Unicode Support) icon

The icon is a shortcut to the command that runs SAS in Unicode mode

"C:\Program Files\SASHome\SASFoundation\9.4\sas.exe" -CONFIG "C:\Program Files\SASHome\SASFoundation\9.4\nls\u8\sasv9.cfg"

Note: Use the right mouse button to pin the icon to the Windows Start Menu or Task bar. You can also use the Windows search bar and type "Unicode Support" to find the icon.

I use a website such as https://unicode-table.com to find the Unicode characters I want to Copy and Paste into my SAS editor, or text files (Notepad++)

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 19:20:22 GMT

@FreelanceReinh wrote:

Hello Paige,

For me it works if I use the "(*ESC*)" notation instead of the ODS ESCAPECHAR in the PROC FORMAT step
value weightf 0-59='<60'  60-high="(*ESC*){Unicode '2265'x}60";
(as @Ksharp did three days ago in another thread -- credit to him).

This works! Thanks!

Re: Using Unicode Characters in PROC SGPLOT (or any other SG PROC)

PaigeMiller — Mon, 18 Jul 2022 19:38:43 GMT

Thank you for the explanation @RichardDeVen

I always have used the SAS 9.4 (English) with a custom autoexec, what is different if I use SAS 9.4 (Unicode)? What do I gain or lose?