topic Re: Only showing Month from date9 in SAS Programming

Only showing Month from date9

ccaudillo100 — Tue, 12 Jul 2022 19:35:32 GMT

Hello,

In my table I have the date in date9. I am wanting to make a new column with just the month. Any examples on how to quickly do this?

Re: Only showing Month from date9

MarkusWeick — Tue, 12 Jul 2022 19:39:01 GMT

Hi @ccaudillo100,

would the MONTH function a possibility for you:

SAS Help Center: MONTH Function

Best

Markus

Re: Only showing Month from date9

PaigeMiller — Tue, 12 Jul 2022 19:39:08 GMT

No need to make a new column. Just change the format. Use format MONNAME.

Re: Only showing Month from date9

Reeza — Tue, 12 Jul 2022 19:40:19 GMT

Month number? Month name?

Just the value or format the variable to look like just the month?

data demo;
mydate=today();
month_num = month(mydate);
month_name = put(mydate, monname3.);
month_num_fmt=mydate;
month_nam_fmt=mydate;
format mydate date9. month_num_fmt month. month_nam_fmt monname3.;
run;

proc print data=demo;
run;

@ccaudillo100 wrote:

Hello,

In my table I have the date in date9. I am wanting to make a new column with just the month. Any examples on how to quickly do this?

Re: Only showing Month from date9

ccaudillo100 — Tue, 12 Jul 2022 19:41:13 GMT

I am needing to make it a new column for a visual I am making. I need to keep the date9 because I delete information if it is before or after a certain date

Re: Only showing Month from date9

Tom — Tue, 12 Jul 2022 19:43:56 GMT

Do you need a new variable or are you just looking to print or group by the month in some report (or analysis)?

If the later then just use a different format with the existing variable.

proc means data=have;
  class date ;
  format date yymm7.;
run;

If the former than you could just map the date to the first of the month. That way the value is still a date, but all of the observations from the same month will have the same value.

month = intnx('month',date,0,'b');
format month yymm7.;

Should it include the year and the month? Or just the month? Do you want the name of the month? Or the number?

Do you want a string? You could use the PUT() function with the appropriate format.

month_string=put(date,yymm7.);

Re: Only showing Month from date9

PaigeMiller — Tue, 12 Jul 2022 19:48:15 GMT

@ccaudillo100 wrote:

I am needing to make it a new column for a visual I am making. I need to keep the date9 because I delete information if it is before or after a certain date

You can use the variable with the MONNAME format in your visual. You can still delete the information if it is before or after a certain date, even after you change the format. Changing the format does not change the underlying (unformatted) value, and SAS always uses the underlying (unformatted) value to do logical operatoins. So if you use the MONNAME format, you can still do things like

where date < '01JAN2019'd

and it will work just fine (because SAS uses the unformatted value always 100% of the time).

Re: Only showing Month from date9

Reeza — Tue, 12 Jul 2022 20:12:14 GMT

Technically not required, you can use the date in different formats in different places.

proc sgplot data=sashelp.stocks;
where stock='IBM' and date >= '06Jun1994'd;
series x=date y=open;
series x=date y=close;
format date monname3.;
run;

@ccaudillo100 wrote:

I am needing to make it a new column for a visual I am making. I need to keep the date9 because I delete information if it is before or after a certain date