topic Re: Start indexing based on given value. in SAS Programming

Start indexing based on given value.

sascode — Fri, 08 Jul 2022 01:33:23 GMT

Hello,
I have a binary variable for each id like this:
ID Binary wanted(index)
1 0 0
1 0 0
1 1 0
1 0 1
1 0 2
1 0 3
2 0 0
2 1 0
2 0 1
3 1 0
3 0 1
......................
So assuming I have only first two variables,how I can generate third wanted(index)?
Note:Within each id, if binary before 1 is 0 then index is 0,then,when reaches 1,index starts from 0 and assigns index counts for each 0 after 1.
For instance, for ID 3 there are not 0 before 1 at binary, therefore it starts indexing directly.
Thanks.

Re: Start indexing based on given value.

andreas_lds — Fri, 08 Jul 2022 04:51:51 GMT

You need

a data step with "by Id"
"retain" to preserve the values of "index" and a helper-variable (increase)
reset index and increase when the a new id is read for the first time

data want;
	set have;
	by id;
	
	retain index increase;
	
	if first.id then do;
		index = 0;
		increase = 0;
	end;
	
	if binary then do;
		increase = 1;
	end;
	
	output;
	
	index = index + increase;
	
	drop increase;
run;

Re: Start indexing based on given value.

sascode — Fri, 08 Jul 2022 05:07:19 GMT

I appreciate your help.
Thank you.