topic Re: Add flag if the condition is true with in same group. in SAS Programming

Add flag if the condition is true with in same group.

Spintu — Fri, 01 Jul 2022 12:19:58 GMT

How to add flag if the condition is true in same group.

The below table as an example with in vendor_id group if the community is 'Y' then I need a new add variable flag as "Y"

Pract_id	Vendor_ID	Community
11	101
12	101	Y
13	101
14	102
15	102
16	103
17	103	Y
18	104	Y

Want output:

Pract_id	Vendor_ID	Community	CBF
11	101		Y
12	101	Y	Y
13	101		Y
14	102
15	102
16	103		Y
17	103	Y	Y
18	104	Y	Y

I am trying for this code. However it is not working.

proc sql;
	create table want as
		select *,'Y' as CBF
			from have
				group by Vendor_ID
					having Community='Y'
						order by vend_bsid;
quit;

Re: Add flag if the condition is true with in same group.

PaigeMiller — Fri, 01 Jul 2022 12:40:57 GMT

UNTESTED CODE

proc freq data=have;
    by vendor_id;
    table community/out=_counts_;
run;
data want;
    merge have _counts_(rename=(community=community1) where=(community1='Y'));
    by vendor_id;
    if count>=1 then CBF='Y';
    drop community1 count percent;
run;

If you want tested code, please provide data as SAS data step code (example)(instructions). We can't write code to work from screen captures.

Re: Add flag if the condition is true with in same group.

maguiremq — Fri, 01 Jul 2022 12:45:27 GMT

data have;
infile datalines missover;
input Pract_id	Vendor_ID	Community $;
datalines;
11	101	 
12	101	Y
13	101	 
14	102	 
15	102	 
16	103	 
17	103	Y
18	104	Y
;

proc sql;
	create table 	want as
		select
					a.*,
					b.cbf
		from
					have as a
						left join
					(
						select
									distinct vendor_id as vendor_id_d,
									community as cbf
						from
							 		have
						where
									community = 'Y'
					) as b
						on	a.vendor_id = b.vendor_id_d;
quit;

Re: Add flag if the condition is true with in same group.

Spintu — Fri, 01 Jul 2022 12:51:38 GMT

Thank You. I tested this is working fine.

Re: Add flag if the condition is true with in same group.

Ksharp — Sat, 02 Jul 2022 06:29:56 GMT

data have;
infile datalines missover;
input Pract_id	Vendor_ID	Community $;
datalines;
11	101	 
12	101	Y
13	101	 
14	102	 
15	102	 
16	103	 
17	103	Y
18	104	Y
;

proc sql;
	create table 	want as
select *,max(Community) as CBF  from have group by Vendor_ID order by 1;
quit;

Re: Add flag if the condition is true with in same group.

Tom — Sat, 02 Jul 2022 14:37:02 GMT

You can just remerge the data with the records where the existing flag is true.

data have;
  length Vendor_ID Pract_id 8 Community $1;
  input Pract_id	Vendor_ID	Community ;
datalines;
11	101	. 
12	101	Y
13	101	. 
14	102	. 
15	102	. 
16	103	. 
17	103	Y
18	104	Y
;

data want;
   merge have 
         have(keep=vendor_id community rename=(community=CBF) where=(CBF='Y'))
   ;
   by Vendor_id;
run;

proc print;
run;

       Vendor_
Obs       ID      Pract_id    Community    CBF

 1       101         11                     Y
 2       101         12           Y         Y
 3       101         13                     Y
 4       102         14
 5       102         15
 6       103         16                     Y
 7       103         17           Y         Y
 8       104         18           Y         Y

Re: Add flag if the condition is true with in same group.

Spintu — Sat, 02 Jul 2022 18:04:47 GMT

Thank you

Re: Add flag if the condition is true with in same group.

Spintu — Sat, 02 Jul 2022 18:05:51 GMT

Thank you

Re: Add flag if the condition is true with in same group.

tarheel13 — Sat, 02 Jul 2022 18:16:04 GMT

I see you already have solution but I would've done it with retain statement.

proc sort data=have;
    by vendor_id descending community;
run;

data have2;
    set have;
    by vendor_id descending community;
    retain cbf;
    if first.vendor_id then cbf='';
    if first.vendor_id and community='Y' then cbf='Y';
run;

Re: Add flag if the condition is true with in same group.

Spintu — Sun, 03 Jul 2022 13:31:04 GMT

Thank you