topic Re: how to find , how many pages in one rtf file by using SAS code in SAS Programming

how to find , how many pages in one rtf file by using SAS code

thanikondharish — Thu, 23 Jun 2022 10:27:30 GMT

My query is like we have one rtf file . So just i checked manually like 10 pages are there .
how to do in sas code to find the no.of pages in rtf file

Re: how to find , how many pages in one rtf file by using SAS code

SASJedi — Thu, 23 Jun 2022 12:22:41 GMT

Not all applications that create RTF files store the number of pages in the document metadata. But if the RTF you are working with was created in Microsoft Word, that information is available as metadata in the RTF file and you can extract it like this:

data rtfinfo;
   Length Author $50 Pages Words 8;
   if _n_=1 then do;
      rxAuthor=prxparse('!\\author\s?([^}]*)}!');
      rxDate=prxparse('!\\creatim\s?\\yr(\d*)\\mo(\d*)\\dy(\d*)!');
      rxPages=prxparse('!\\nofpages\s?(\d*)}!');
      rxWords=prxparse('!\\nofwords\s*(\d*)}!');
   end;
   retain rx:;
   drop rx:;
   infile 'C:\temp\myrtf.rtf' end=eof;
   do until (eof);
      input;
      if prxmatch(rxAuthor,_infile_) then do;
         Author=prxposn(rxAuthor,1,_infile_);
         put Author=;
      end;
      if prxmatch(rxPages,_infile_) then do;
         Pages=input(prxposn(rxPages,1,_infile_),32.);
         put Pages=;
      end;
      if prxmatch(rxWords,_infile_) then do;
         Words=input(prxposn(rxWords,1,_infile_),32.);
         put Words=;
      end;
      if sum(missing(Author),missing(Pages),missing(Words))=0 then do;
         output;
         stop;
      end;
   end;
run;

This code produces an output that looks like this:

Obs	Author	Pages	Words
1	Mark Jordan	4	16

Re: how to find , how many pages in one rtf file by using SAS code

thanikondharish — Thu, 23 Jun 2022 21:58:39 GMT

I have a text in one RTF file so I have to read that text into sas and
create one dataset

text ---> This is awesome

Re: how to find , how many pages in one rtf file by using SAS code

SASJedi — Mon, 27 Jun 2022 12:15:38 GMT

RTF is a format designed to present information best formatted for human consumption and is not well suited for machine-reading. Significant SAS programming and a good knowledge of RTF structure are required to extract data from an RTF. Here are some good references to get you started:

RTF file specifications
How to read RTF files into SAS® datasets? by Chunpeng Zhao
Importing Data from RTF Output into SAS® utilizing Microsoft® Access/Word in an intriguing, efficient way - Ajay Gupta and Matthew Lesko
The readrtf macro