Create a List from Column

david27 — Wed, 25 May 2022 19:24:34 GMT

Team,

This is what I have:

data have;
input have $12.;
datalines;
1
2
3
4,5
6,7,8
1
;
run;

I want all the values in single macro variable separated by comma(,)

want='1','2','3','4','5','6','7','8'

Re: Create a List from Column

Reeza — Wed, 25 May 2022 19:41:02 GMT

data have;
input have $12.;
datalines;
1
2
3
4,5
6,7,8
1
;
run;

*create temporary view of data with a row for each value;
data _temp / view = _temp;
set have;

nterms= countw(have);
do i=1 to nterms;
value = scan(have, i);
output;
end;
run;

proc sql noprint;
*add all DISTINCT values into macro variable;
select distinct quote(trim(value), "'") into :var_list separated by ", " from _temp;
*drop temporary view;
*drop view _temp;
quit;


%put &var_list.;

@david27 wrote:

Team,

This is what I have:
data have;
input have $12.;
datalines;
1
2
3
4,5
6,7,8
1
;
run;
I want all the values in single macro variable separated by comma(,)
want='1','2','3','4','5','6','7','8'

topic Re: Create a List from Column in SAS Programming

Create a List from Column

Re: Create a List from Column