topic Re: PROC UNIVARIATE turns output in scientific notation in SAS Programming

PROC UNIVARIATE turns output in scientific notation

MerAgSo — Sun, 15 May 2022 18:14:49 GMT

Hi,

I am trying to run a proc univariate for a large dataset, but some of the variables' output is expressed in scientific notation and I want the absolute numbers. I can change them manually but would rather do it auotmatically.

Here is my code:

proc univariate data=corregida normaltest;
var edad INL bmi;

run;

Thank you.

Re: PROC UNIVARIATE turns output in scientific notation

PaigeMiller — Sun, 15 May 2022 20:00:03 GMT

Normally, if the output contains 12 or more digits to the left of the decimal, the default is to create results in scientific notation.

Instead of the output as a printed report, you can ask PROC UNIVARIATE to output the results to a SAS data set, and then apply whatever format you want to change the appearance. And then print it whatever way you please with the formatted values.

Re: PROC UNIVARIATE turns output in scientific notation

Rick_SAS — Sun, 15 May 2022 20:20:22 GMT

Use ODS OUTPUT to create a data set that contains the statistics. Then use PROC PRINT to display the value in whatever format you want. For example, the following captures two output tables and uses the 20.16 format to print the numerical values of the statistics:

data corregida;
call streaminit(123);
do i = 1 to 100;
   edad=rand("normal",0,1e-10);
   output;
end;
run;

ods trace on;
proc univariate data=corregida normaltest;
var edad ; 
ods output Moments=Moments
           BasicMeasures=BM;
run;

proc print data=Moments;
format nValue1 nValue2 20.16;
run;

proc print data=BM;
format locValue VarValue 20.16;
run;