topic Re: Getting exponential value in SAS Programming

Getting exponential value

Rahul_SAS — Thu, 12 May 2022 16:07:34 GMT

Hi Experts,

Can anyone tell me why i am getting exponential value for third observation.

data test;
infile datalines dlm=',';
input name $ salary;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,4524542145214
sagar adirala bahu,111111111111
;
run;

Re: Getting exponential value

Reeza — Thu, 12 May 2022 16:26:40 GMT

Value is too wide 13chars and default format won't display it correctly.

Explicitly specify your format.

data test;
infile datalines dlm=',';
input name $ salary;
format name $50. salary Best32.;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,4524542145214
sagar adirala bahu,111111111111
;
run;

@Rahul_SAS wrote:

Hi Experts,

Can anyone tell me why i am getting exponential value for third observation.

data test;
infile datalines dlm=',';
input name $ salary;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,4524542145214
sagar adirala bahu,111111111111
;
run;

Re: Getting exponential value

Rahul_SAS — Thu, 12 May 2022 16:35:02 GMT

Hi Reeza,

Completely agree with your statement.

However here, I have 2 questions-

1. SAS supports default 8 bytes so only 5 digits should have been read not 12 digits.

2. I have an understanding that while creating a table in a data warehouse we should keep numeric columns so that it will occupy less storage whereas character columns will consume more storage space.

Re: Getting exponential value

Reeza — Thu, 12 May 2022 16:42:01 GMT

Regarding 1, see this page.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/lepg/p0dv87zb3bnse6n1mqo360be70qr.htm

8 bytes is numbers as large as 9,007,199,254,740,992

2. Yes they should be numeric, so use 32. if you'd like.

I said character, but I was referring to the number of digits. The default width of the format doesn't display the desired amount of digits is more accurate.

@Rahul_SAS wrote:

Hi Reeza,

Completely agree with your statement.

However here, I have 2 questions-

1. SAS supports default 8 bytes so only 5 digits should have been read not 12 digits.

2. I have an understanding that while creating a table in a data warehouse we should keep numeric columns so that it will occupy less storage whereas character columns will consume more storage space.

Re: Getting exponential value

ballardw — Thu, 12 May 2022 16:46:10 GMT

@Rahul_SAS wrote:

Hi Reeza,

Completely agree with your statement.

1. SAS supports default 8 bytes so only 5 digits should have been read not 12 digits.

You want to look at what "fits" in 8 bytes. Why would 8 bytes be restricted to 5 digits ever?

From documentation for Windows

Significant Digits and Largest Integer by Length for SAS Variables under Windows
Length in Bytes	Largest Integer Represented Exactly	Exponential Notation	Significant Digits Retained
3	8,192	2¹³	3
4	2,097,152	2²¹	6
5	536,870,912	2²⁹	8
6	137,438,953,472	2³⁷	11
7	35,184,372,088,832	2⁴⁵	13
8	9,007,199,254,740,992	2⁵³	15

Re: Getting exponential value

Tom — Thu, 12 May 2022 16:57:54 GMT

PROC PRINT will default to using BEST12. format to display numeric variables that have no format attached to them.

Use a different format to display the variable.

data test;
  infile datalines dsd ;
  input name :$30. salary;
  format salary comma20.;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,4524542145214
sagar adirala bahu,111111111111
;

proc print;
run;

Re: Getting exponential value

Rahul_SAS — Thu, 12 May 2022 17:40:16 GMT

Hi Reeza/Ballardw,

Even using the values given in the table are not working as expected.

data test;
infile datalines dlm=',';
input name $ salary 8.;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,9007199254740992
sagar adirala bahu,72057594037927936
;
run;

Its returning only 8 digits even after applying 8. format.

Largest Integer That Can Be Safely Stored in a Given Length
When Variable Length Equals ...	Largest Integer z/OS	Largest Integer Windows or UNIX
2	256	not applicable
3	65,536	8,192
4	16,777,216	2,097,152
5	4,294,967,296	536,870,912
6	1,099,511,627,776	137,438,953,472
7	281,474,946,710,656	35,184,372,088,832
8 (default)	72,057,594,037,927,936	9,007,199,254,740,992

Significant Digits and Largest Integer by Length for SAS Variables under Windows
Length in Bytes	Largest Integer Represented Exactly	Exponential Notation	Significant Digits Retained
3	8,192	2¹³	3
4	2,097,152	2²¹	6
5	536,870,912	2²⁹	8
6	137,438,953,472	2³⁷	11
7	35,184,372,088,832	2⁴⁵	13
8	9,007,199,254,740,992	2⁵³	15

Re: Getting exponential value

Reeza — Thu, 12 May 2022 17:47:02 GMT

Length and Formats are not the same thing.

A format controls how many digits/characters are displayed.

A length controls how many digits/characters are stored in the underlying system.

data test;
infile datalines dlm=',';
length salary 8;
format salary best32.;
input name $ salary;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,9007199254740992
sagar adirala bahu,72057594037927936
;
run;

proc print data=test;
format salary best32.;
run;

Re: Getting exponential value

Reeza — Thu, 12 May 2022 17:47:44 GMT

And an informat controls tells SAS how the variable should be read in, ie what format to expect the variable in.

Re: Getting exponential value

AMSAS — Thu, 12 May 2022 17:47:48 GMT

@Rahul_SAS You are confusing 3 different SAS terms

Length - This is the amount of "Ram/Disk used to store a variable"
Format - This is the way to display a variable
Informat - This is the way SAS reads a variable

In your code (below) you are telling SAS to create a variable salary, it will have a default length of 8 bytes, by reading just 8 numeric characters
So your 1st record which has 400000455225 as the second variable, SAS only reads the first 8 characters 400000455

data test;
infile datalines dlm=',';
input name $ salary 8.;
datalines;
venkat pati raju,400000455225
vivek rattakonda murali,425
kiran kumar segu,9007199254740992
sagar adirala bahu,72057594037927936
;
run;