topic Re: Proc transpose altenative methods in SAS Programming

Proc transpose altenative methods

BrahmanandaRao — Mon, 02 May 2022 06:44:51 GMT

data long_data;
    input team $ variable $ value;
    datalines;
A Points 88
A Assists 12
A Rebounds 22
B Points 91
B Assists 17
B Rebounds 28
C Points 99
C Assists 24
C Rebounds 30
D Points 94
D Assists 28
D Rebounds 31
;
run;


proc transpose data=long_data out=wide_data name=variables;
    by team;
    id variable;
    var value;
run;

Re: Proc transpose altenative methods

japelin — Mon, 02 May 2022 06:56:59 GMT

What do you want to do?
Please describe your question properly.

Re: Proc transpose altenative methods

BrahmanandaRao — Mon, 02 May 2022 07:09:49 GMT

any alternative methods instead of proc transpose

Re: Proc transpose altenative methods

japelin — Mon, 02 May 2022 07:21:41 GMT

One way is to use the data step.

proc sort data=long_data out=sorted;
  by team;
run;
data wide_data2;
  set sorted;
  by team;
  retain points assists rebounds;
  if first.team then do;
    Points=.;
    Assists=.;
    Rebounds=.;
  end;
  if variable='Points'   then Points=value;
  if variable='Assists'  then Assists=value;
  if variable='Rebounds' then Rebounds=value;
  if last.team;
  keep team  points assists rebounds;
run;

Re: Proc transpose altenative methods

BrahmanandaRao — Mon, 02 May 2022 07:26:44 GMT

Using array method is it possible

Re: Proc transpose altenative methods

Ksharp — Mon, 02 May 2022 10:08:00 GMT

data long_data;
    input team $ variable $ value;
    datalines;
A Points 88
A Assists 12
A Rebounds 22
B Points 91
B Assists 17
B Rebounds 28
C Points 99
C Assists 24
C Rebounds 30
D Points 94
D Assists 28
D Rebounds 31
;
run;
proc sql noprint;
select distinct catt('long_data(where=(variable="',variable,'") rename=(value=',variable,'))')
 into :merge separated by ' '
  from long_data;
quit;

data want;
 merge &merge.;
 by team;
drop variable;
run;

Re: Proc transpose altenative methods

PaigeMiller — Mon, 02 May 2022 12:51:43 GMT

@BrahmanandaRao wrote:
Using array method is it possible

No array for your data

Re: Proc transpose altenative methods

Tom — Mon, 02 May 2022 13:33:20 GMT

@BrahmanandaRao wrote:
Using array method is it possible

What variable would you use as the index into the array?