topic Re: Using output to statement to output different values in SAS Programming

Using output to statement to output different values

Tommer — Thu, 31 Mar 2022 15:03:52 GMT

Hello,

The dataset I have is :

data subj0;
input subj $4. sex $2. age;
datalines;
101 M 23
102 F 25
103 F 28
104 23
105 F 24
106 M .
107 F 28
108 22
109 F 25
110 F .
111 .
;
run;

Some subjects have missing sex but age is available, for those subjects I am trying to populate them as both 'M' and 'F' as separate records. I have tried using the below output statement but unsure where I am going wrong as it stops at second output statement. For the third output statement to work, the condition is still met (ie. missing sex and age is present) but it is not running.

data exp;
set subj0;
output;
if sex=" " and age ne . then do;
sex="M";
output;
end;
if sex=" " and age ne . then do;
sex="F";
output;
end;
run;

Re: Using output to statement to output different values

Tom — Thu, 31 Mar 2022 15:11:26 GMT

Do you want the new dataset to have three versions of the observations that had a missing value for SEX? That is what you coded. Or did you want two observations?

It sounds like you want to use only one IF statement.

So if you want three observations do:

output;
if sex=" " and age ne . then do;
  sex="M";
  output;
  sex="F";
  output;
end;

If you only want two observations for those records then do:

if sex=" " and age ne . then do;
  sex="M";
  output;
  sex="F";
  output;
end;
else output;

Re: Using output to statement to output different values

Tommer — Thu, 31 Mar 2022 15:25:13 GMT

Thank you so much Tom! Any idea what I was doing incorrectly? My understanding is using 'end' just closes the do block. When I have the next Do block, I thought it would run normally as a separate Do block and output, which was not. If you have a minute would you mind helping me understand?

Re: Using output to statement to output different values

Tom — Thu, 31 Mar 2022 15:53:45 GMT

The statements were perfectly valid.

Your LOGIC was flawed.

The first IF block executed and changed SEX to 'M'.

So the second IF block never executed.

Re: Using output to statement to output different values

Tommer — Thu, 31 Mar 2022 16:20:28 GMT

My logic was after the first two output statements in my code, there are still rows with missing sex and not missing age (the second do block converted missing to "M" but from the first Do block we have missing sex) which will be the input for the third Do block.

Re: Using output to statement to output different values

Tom — Thu, 31 Mar 2022 16:27:14 GMT

@Tommer wrote:
My logic was after the first two output statements in my code, there are still rows with missing sex and not missing age (the second do block converted missing to "M" but from the first Do block we have missing sex) which will be the input for the third Do block.

I cannot figure out what you are saying.

Try it with a manipulative. Use a piece of paper to represent the variable SEX for one observation read by the SET statement. It will start as blank. Now write the letter M on it. Now read it. What does it say? Is it still blank? Or does it have the letter M on it?

Re: Using output to statement to output different values

Tommer — Thu, 31 Mar 2022 18:09:21 GMT

My thought process for how 'output' works was way off. Played around a bit to understand better, thanks Tom.