topic Re: Create Datasets Based on Contents in SAS Programming

Create Datasets Based on Contents

david27 — Wed, 30 Mar 2022 14:01:37 GMT

So I have this information:

Name of the variable
Type( Character / Numeric)
Length
Format

Based on this information, I am required to produce a SAS Dataset with an additional date variable- YearMonth (YYYYMM)

We can populate the values inside the variable randomly.

The list of variables can be 2, 10 or 50.(var1 , var2, var3.....)

HAVE:

/*HAVE*/
data have;
infile datalines missover ;
input varname :$8. type length format $8.;
datalines;
var1 1 8 
var2 1 8 
var3 2 8 
var4 2 1 
var5 1 8 
;run;

WANT:

YEARMONTH	VAR1	VAR2	VAR3	VAR4	VAR5
202002	1	2	A	B	5
202003	3	3	C	D	6
202004	4	4	E	F	7
202005	5	5	G	H	8

Please advise.

Thank You

Re: Create Datasets Based on Contents

PaigeMiller — Wed, 30 Mar 2022 15:06:44 GMT

Please explain the logic that results in 202002 in the first row, 202003 in the second row, and so on. Thanks!

Re: Create Datasets Based on Contents

Tom — Wed, 30 Mar 2022 15:48:07 GMT

If you want to define variables from metadata then just use some type of code generation.

For example you could generate a series of ATTRIB statements.

filename code temp;
data _null_;
  set have ;
  file code ;
  length name $51 ;
  name=nliteral(varname);
  put 'attrib ' name 'length=' @;
  if type=2 then put '$' @;
  put length @;
  if not missing(format) then put format= @;
  put ';';
run;

You could then use those statements inside a data step to define the variables.

data want;
  do yearmonth = '202002','202003','202004';
%include code / source2;
    output;
  end;
run;

Re: Create Datasets Based on Contents

david27 — Wed, 30 Mar 2022 17:08:27 GMT

Thank You very much @Tom