topic Re: How to modify correlation plot x and y axis to have the same scale and begin at the origin? in SAS Programming

How to modify correlation plot x and y axis to have the same scale and begin at the origin?

mdphdUTMB — Tue, 29 Mar 2022 01:14:59 GMT

Can someone tell me how to modify a correlation plot to have the same scale for the x and y axis that begins at the origin?

When I use my current code below, my graph "zooms in", but I want to display it differently.

ods graphics on;
PROC CORR DATA=TBI1 PLOTS=SCATTER(NVAR=all);
VAR D16MWT D26MWT;
RUN;
ods graphics off;

graph:

Thank you in advance!

Re: How to modify correlation plot x and y axis to have the same scale and begin at the origin?

Rick_SAS — Tue, 29 Mar 2022 10:52:32 GMT

It sounds like you should use PROC SGPLOT if you want complete control over axes ranges. Compare the following two plots:

proc corr data=sashelp.class plots=scatter;
var weight height;
run;

title "Scatter Plot";
title2 "With 95% Prediction Ellipse";
proc sgplot data=sashelp.class;
   scatter x=weight y=height;
   ellipse  x=weight y=height;
   xaxis min=0;  /* do you also want MAX=500 ? */
   yaxis min=0;  /* do you also want MAX=500 ? */
run;

I'm not sure if " the same scale for the x and y axis" means that you also want the maximum value for each axis to be the same. If so, use the MAX= option on the XAXIS and YAXIS statements, as shown in the comments.

Re: How to modify correlation plot x and y axis to have the same scale and begin at the origin?

Ksharp — Tue, 29 Mar 2022 12:08:13 GMT

Rick have already given you answer. My code is the same as him .

proc sgplot data=sashelp.class aspect=1 noautolegend;
scatter x=weight y=height;
ellipse x=weight y=height/ alpha=0.05;
inset 'obs =19' 'Corr =0.877' 'Pvalue=<.0001';
xaxis min=0;
yaxis min=0;
run;