topic Re: Convert string to timestamp in SAS Programming

Convert string to timestamp

Hansmuffs — Wed, 16 Mar 2022 10:47:19 GMT

Hi,

this is my string 14.03.2022 08:00:50 Input is $20. How to convert this string to timestamp?

The code below give back empty field BEGINN.

  data &wkLibname..F_DATA;
    format
      BEGINN_TMP DATETIME26.;
    set &wkLibname..DATA_RAW;
      BEGINN_TMP = input(BEGINN, NLDATM.);
      DROP BEGINN;
      RENAME BEGINN_TMP = BEGINN;
  run;

Re: Convert string to timestamp

maguiremq — Wed, 16 Mar 2022 11:07:07 GMT

data have;
input beginn $20.;
datalines;
14.03.2022 08:00:50
;
run;

data want;
	set have;
		beginn_tmp = input(beginn, ANYDTDTM.);
	format beginn_tmp datetime19.;
run;

Remove the FORMAT if you don't want it formatted.

Re: Convert string to timestamp

Kurt_Bremser — Wed, 16 Mar 2022 12:22:17 GMT

I really do not like the vagaries of the "ANY" informats, so I force correct informats for the date and time part:

data have;
input beginn $20.;
datalines;
14.03.2022 08:00:50
;

data want;
set have (rename=(beginn=_beginn));
format beginn e8601dt19.;
beginn = dhms(
  input(scan(_beginn,1," "),ddmmyy10.),
  0,
  0,
  input(scan(_beginn,2," "),time8.)
);
drop _beginn;
run;

Re: Convert string to timestamp

FreelanceReinh — Wed, 16 Mar 2022 13:30:05 GMT

Hi @Hansmuffs,

Your code should work well if you are using the typical German setting of system option LOCALE, i.e.

options locale=DE_DE;

It also works with some other locales, e.g., FR_FR or EN_GB, but not with EN_US (which in turn works with '03.14.2022 08:00:50').