topic Re: To create a variable COUNTS which will have the counts of outliers. in SAS Programming

To create a variable COUNTS which will have the counts of outliers.

Santt0sh — Wed, 16 Mar 2022 01:12:30 GMT

Hi All,

I m trying to capture the count of the Outliers. I have used the below code.

DATA A;
INPUT A B C;
DATALINES;
1 2 3
1 2 3
45 45 66
34 556 334
;

PROC UNIVARIATE DATA=A OUTTABLE=A1;
VAR A;
RUN;

DATA A2;
SET A1;
UPPER=_Q1_ *(1.5 + _QRANGE_);
LOWER=_Q3_ *(1.5 - _QRANGE_);
CALL SYMPUT('UPPER', UPPER);
CALL SYMPUT('LOWER', LOWER);
RUN;

%PUT &UPPER. &LOWER.;

DATA X;
U="&UPPER.";
L="&LOWER.";
RUN;

DATA X;
SET A;
WHERE A GE &UPPER. OR A LE &LOWER.;
RUN;

DATA X1;
SET A;
WHERE A GE &UPPER. ;
RUN;

DATA X2;
SET A;
WHERE A LE &LOWER.;
RUN;

Re: To create a variable COUNTS which will have the counts of outliers.

PGStats — Wed, 16 Mar 2022 02:42:45 GMT

Here is an example of robust outlier detection in biological data (sampled fish measurements):

/* Calculate a body mass index (BMI) for each sampled fish */
data have;
set sashelp.fish;
BMI= weight / length1**3;
run;

/* identify the BMI outliers (fish that are too thin or too fat) */
proc robustreg data=have;
where species in  ("Perch" "Roach");
by species notsorted;
model BMI = / diagnostics(all);
output out=want outlier=outlier residual=residual;
run;

/* Report on the number of outliers for each species */
proc sql;
select * 
from want
where outlier;
select 
    species, 
    sum(outlier) as count
from want
group by species;
quit;

Re: To create a variable COUNTS which will have the counts of outliers.

Santt0sh — Wed, 16 Mar 2022 03:37:49 GMT

Hi,

Thanks let me try this!

Regards

Re: To create a variable COUNTS which will have the counts of outliers.

Santt0sh — Sat, 19 Mar 2022 11:45:52 GMT

Thank you for the suggestion!!
It worked

Re: To create a variable COUNTS which will have the counts of outliers.

PaigeMiller — Sat, 19 Mar 2022 12:48:36 GMT

@Santt0sh

Please mark the reply from @PGStats as the correct answer, and unmark your own reply as the answer.