topic Re: Background color of legend in sgplot in SAS Programming

Background color of legend in sgplot

AntjeWestphal — Fri, 11 Mar 2022 12:00:20 GMT

Hi!

My plot has WALLCOLOR=LTGRAY. Is it possible to have that color as background in the legend too?

Here is a part of the syntax:

PROC SGPLOT DATA = DB;
styleattrs datacontrastcolors=(red blue green magenta yellow black) WALLCOLOR=LTGRAY
             datasymbols=(x x x circle circle circle Triangle Triangle Triangle);
   SERIES X = date Y = Wert / markers lineattrs=(pattern=solid) markerattrs=(size=11) group = Nr;
   keylegend/position=bottom valueattrs=(family=arial size=12pt) down=3;
...

Best regards 🕊

Antje

Re: Background color of legend in sgplot

Ksharp — Fri, 11 Mar 2022 12:56:41 GMT

Do you mind to put it inside graph ?

   keylegend/position=bottom valueattrs=( family=arial size=12pt) down=3 location=inside;

Re: Background color of legend in sgplot

Ksharp — Fri, 11 Mar 2022 13:04:44 GMT

Or if you want make backcolor be LTGRAY ?

PROC SGPLOT DATA = SASHELP.HEART ;
styleattrs datacontrastcolors=(red blue green magenta yellow black)
WALLCOLOR=LTGRAY backcolor=LTGRAY
             datasymbols=(x x x circle circle circle Triangle Triangle Triangle);
   SERIES X = weight Y = height / markers lineattrs=(pattern=solid) markerattrs=(size=11) group = bp_status;
   keylegend/position=bottom   valueattrs=( family=arial size=12pt) down=3 NOOPAQUE  

;
run;

Re: Background color of legend in sgplot

AntjeWestphal — Fri, 11 Mar 2022 13:46:10 GMT

Thanks, @Ksharp!

If there is no other option to get only a grey background of the legend, I would choose your second idea.

Re: Background color of legend in sgplot

BrunoMueller — Fri, 11 Mar 2022 15:49:54 GMT

The KEYLEGEND statement does not support to set the background. Proc SGPLOT code is translated into the Graph Template Language (GTL), on this level it is possible to set the background of the legend.

How to get the GTL from Proc SGPLOT, add the TMPLOUT= option, see below.

proc sgplot data=sashelp.class tmplout="c:\temp\sgplot.sas";
  styleattrs
  datacontrastcolors=(red blue green magenta yellow black) WALLCOLOR=LTGRAY
    datasymbols=(x x x circle circle circle Triangle Triangle Triangle);
  series x=age y=height / group=sex;
  keylegend / location=outside ;
run;

Have a look at the resulting file, this the GTL code used to create the graph.

Now adapt the code by adding the BACKGROUND= option to the DISCRETELEGEND statement, see below for an example.

ods path
  (prepend) work.mytemplates (update)
;

proc template;
define statgraph sgplot;
begingraph / collation=binary subpixel=on dataContrastColors=( CXFF0000 CX0000FF CX008000 CXFF00FF CXFFFF00 CX000000 ) dataSymbols=( X X X CIRCLE CIRCLE CIRCLE TRIANGLE TRIANGLE TRIANGLE );
layout overlay / WallColor=CXC0C0C0 yaxisopts=(labelFitPolicy=Split) y2axisopts=(labelFitPolicy=Split);
   SeriesPlot X='Age'n Y='Height'n / primary=true Group='Sex'n LegendLabel="Height" NAME="SERIES";
   DiscreteLegend "SERIES" / Location=Outside Title="Sex" backgroundcolor=ltgray;
endlayout;
endgraph;
end;
run;

proc sgrender data=sashelp.class template=sgplot;
run;

Re: Background color of legend in sgplot

AntjeWestphal — Tue, 15 Mar 2022 20:03:44 GMT

Thanks @BrunoMueller!

I never used proc template before and I have to become acquainted with it.

Re: Background color of legend in sgplot

BrunoMueller — Wed, 16 Mar 2022 17:48:47 GMT

As a general rule always start with proc SGPLOT, SGPANEL etc. Only if there is not other way I would go for the Graph Template Language.

Re: Background color of legend in sgplot

BrunoMueller — Wed, 16 Mar 2022 18:32:09 GMT

Actually there is any easier way which does not involve any GTL, but defining your own style, check out the sample below.

/*
 * have a look at the default style definition
 * search for graphlegendbackground
 */
proc template;
  source styles.default;
run;

/*
 * now create your own style based on the default style you use
 * just change the definition for GraphLegendBackground
 */
proc template;
  define style mystyle;
    parent=styles.htmlblue;
    class GraphLegendBackground /
      backgroundcolor = ltgray
      color = ltgray
  ;
  end;
run;

/*
 * now create the graph using your own style definition
 * et voilà
 */
ods html5 file="c:\temp\legendbackground.html"
          style=mystyle
      ;
      
proc sgplot data=sashelp.class tmplout="c:\temp\sgplot.sas";
  styleattrs
  datacontrastcolors=(red blue green magenta yellow black) WALLCOLOR=LTGRAY
    datasymbols=(x x x circle circle circle Triangle Triangle Triangle);
  series x=age y=height / group=sex;
  keylegend / location=outside ;
run;
ods html5 close;

Also check this paper, https://support.sas.com/resources/papers/proceedings17/SAS0675-2017.pdf, on the various style elements being used.

Re: Background color of legend in sgplot

AntjeWestphal — Mon, 21 Mar 2022 11:33:16 GMT

@BrunoMueller Great, it works perfectly! Thanks for your input and the paper!