Hash table from empty tables

Jakkas — Tue, 04 Feb 2014 21:27:40 GMT

Something interesting is happening when I am trying to create a hash table from a table with no rows. In the following example Temp1 has no rows, Temp2 has one row. I would expect Temp3 to have one row with missing value for x. But Temp3 has no rows. I have this logic in a big data step with multiple hash tables and as soon as one of the hash table input talbe is empty all the subsequent ones fail to load and nothing is written to output tables in the data step. Anyone know why this happens and how to control it? Thank you.

Proc Sql;

Create Table Temp1 (P Char(1), x Num);

Quit;

Data Temp2;

P="A"; y=3; Output;

Run;

Data Temp3(Drop=rc);

Declare Hash myhash();

myhash.DefineKey('P');

myhash.DefineData('x');

myhash.DefineDone();

eof=0;

Do Until(eof);

Set Temp1 end=eof;

rc=myhash.add();

End;

eof=0;

Do Until(eof);

Set Temp2 end=eof;

rc=myhash.find();

output;

End;

Stop;

Run;

Re: Hash table from empty tables

data_null__ — Tue, 04 Feb 2014 21:37:51 GMT

Do while NOT and use different END variables.

Proc Sql; 
   Create Table Temp1 (P Char(1), x Num);
   Quit; 


Data Temp2;
   p="A"; y=3; Output; 
   Run; 


Data Temp3(Drop=rc);
   Declare Hash myhash();
   myhash.DefineKey('P');
   myhash.DefineData('x');
   myhash.DefineDone();
   Do while(not eof1);
      Set Temp1 end=eof1;
      rc=myhash.add();
      End; 
   Do while(not eof2);
      Set Temp2 end=eof2;
      rc=myhash.find();
      output; 
      End; 
   Stop; 
   Run; 
proc print data=temp3;
   run;

topic Hash table from empty tables in SAS Programming

Hash table from empty tables

Re: Hash table from empty tables