topic Re: How do I use an array to check for several values in multiple variables? in SAS Programming

How do I use an array to check for several values in multiple variables?

Geoghegan — Wed, 09 Mar 2022 02:26:41 GMT

I have 30 variables that I'm trying to check through to see if they each match one of several results. If any of those specific results are in even one of those 30 variables, I want a new indicator variable to be equal to 1, and equal to 0 otherwise. I don't care if it's the first variable checked or the last but I seem to only be able to get it to check the last variable for the result options I want. It doesn't give errors, but only shows a few with the new variable equal to 1 and they seem to all be ones where the result is in the D30 variable so I'm guessing I'm missing something that makes it check all of the variables and mark the new variable to 1 no matter which variable it is, but I can't figure out how to fix that. Thank you!

I have this:

data combinedmasternewvars;
set project.combinedmaster;

Array cd(30) $ D1-D30;
do i=1 to 30;
If cd (i) in ("A04" "A05" "A06") then present=1;
Else present=0;
end;
Run;

Re: How do I use an array to check for several values in multiple variables?

pink_poodle — Wed, 09 Mar 2022 02:40:33 GMT

Is your dataset arranged well with D1, D2, D3 … D30 columns in sequence, or is jumbled like D2, D1, D30, D5, because then D1-D30 will look at just D1 and D30. To arrange in sequence, you can precede with a data step retaining the right sequence like data a; retain D1 D2 D3; set combinedmaster; run;

Re: How do I use an array to check for several values in multiple variables?

Reeza — Wed, 09 Mar 2022 03:59:02 GMT

The ELSE always resets it to 0, even after it's been found once. Remove the ELSE and you should have the answer you expect.

data combinedmasternewvars;
set project.combinedmaster;

Array cd(30) $ D1-D30;
present=0;
do i=1 to 30;
If cd (i) in ("A04" "A05" "A06") then present=1;
end;
Run;

@Geoghegan wrote:

I have 30 variables that I'm trying to check through to see if they each match one of several results. If any of those specific results are in even one of those 30 variables, I want a new indicator variable to be equal to 1, and equal to 0 otherwise. I don't care if it's the first variable checked or the last but I seem to only be able to get it to check the last variable for the result options I want. It doesn't give errors, but only shows a few with the new variable equal to 1 and they seem to all be ones where the result is in the D30 variable so I'm guessing I'm missing something that makes it check all of the variables and mark the new variable to 1 no matter which variable it is, but I can't figure out how to fix that. Thank you!

I have this:

data combinedmasternewvars;
set project.combinedmaster;

Array cd(30) $ D1-D30;
do i=1 to 30;
If cd (i) in ("A04" "A05" "A06") then present=1;
Else present=0;
end;
Run;

Re: How do I use an array to check for several values in multiple variables?

Geoghegan — Wed, 09 Mar 2022 02:52:45 GMT

I think D1 is earlier in the dataset and then D2-30 are in order later in
the dataset. Would that make it just look at D30?

Re: How do I use an array to check for several values in multiple variables?

ballardw — Wed, 09 Mar 2022 03:44:36 GMT

Maybe:

data combinedmasternewvars;
   set project.combinedmaster;
   Array cd(30) $ D1-D30;
   Present=0;
   do i=1 to 30;
       If cd (i) in ("A04" "A05" "A06") then do;
            present=1;
            leave;
       end;
   end;
Run;

Set the "not found" before checking the values.

The above with the LEAVE instruction tells SAS to exit the loop set by the Do i= ....; Because the Leave instruction is set to execute conditionally when one of the values is found, it stops searching for the other matches. If none of the variables matches then the not found is the value as it has not been overwritten.

Please note that the code I posted is in a text box opened on the forum using the </> icon so formatting of text is maintained a bit nicer. You could also post in a code box which is opened with the little "running man" icon. The boxes help separate question from code and make pasted text much easier to read (especially if code is indented), or in the case of examples of a text file keep the contents. The message windows on this forum will reformat text and in some cases may result in non-printable characters that mean code copied and pasted from the forum will not execute as expected or at all even when it appears correct.

Re: How do I use an array to check for several values in multiple variables?

pink_poodle — Wed, 09 Mar 2022 04:22:18 GMT

I think that would be ok. If array did not include all 30 variables, the do loop would complain that array subscript is out of range.

Re: How do I use an array to check for several values in multiple variables?

Patrick — Wed, 09 Mar 2022 04:35:49 GMT

or this way.

data combinedmasternewvars;
  set project.combinedmaster;
  array cd {*} $ d1-d30;
  present=0;
  do i=1 to dim(cd) until(present=1);
    if cd[i] in ("A04" "A05" "A06") then
      present=1;
  end;
run;

Re: How do I use an array to check for several values in multiple variables?

Tom — Wed, 09 Mar 2022 04:53:40 GMT

@Geoghegan wrote:
I think D1 is earlier in the dataset and then D2-30 are in order later in
the dataset. Would that make it just look at D30?

The order of the variables in the dataset does not matter.

It is the order of the variables in your ARRAY statement that matters and D30 is the last variable in the array statement. Because you include the ELSE clause only the result of last element in the array matters. Remove the ELSE clause. If you want the new variable coded as 1 or 0 instead of 1 or missing then set it to 0 before the DO loop.

Re: How do I use an array to check for several values in multiple variables?

andreas_lds — Wed, 09 Mar 2022 06:54:53 GMT

Already mentioned: The else-part is causing the problem.

data combinedmasternewvars;
  set project.combinedmaster;

  array cd[30] D1-D30;
  present = 0;
  do i=1 to 30;
    if cd[i] in ("A04" "A05" "A06") then do;
      present=1;
      leave;
    end;
run;

Re: How do I use an array to check for several values in multiple variables?

Geoghegan — Wed, 09 Mar 2022 15:15:41 GMT

Thank you everyone! a few of those variations worked and that makes sense why what I did was messing it up.

I appreciate it!