topic Re: Transpose the data in SAS Programming

Transpose the data

kumarK — Sun, 21 Dec 2014 11:31:30 GMT

Hi frnds...
I have a problem that could be a simple one.
In a dataset I have two variables id and spend
like
data a;
input id spend;
cards;
1 100
1 200
1 300
2 150
2 690
;
run;

I want output like

id jan feb mar
1 100 200 300
2 150 690 .

through arrays or sql share ur simplest code ..thanks in advance

Re: Transpose the data

Ksharp — Sun, 21 Dec 2014 13:25:37 GMT

How about:

data have;
input id spend;
cards;
1 100
1 200
1 300
2 150
2 690
;
run;
data want;
 set have;
 by id;
 array x{*} jan feb mar;
 retain jan feb mar     ;
 if first.id then do;n=0;call missing(of x{*});end;
 n+1;
 x{n}=spend;
 if last.id;
 drop n spend;
run;

Xia Keshan

Re: Transpose the data

naveen_srini — Sun, 21 Dec 2014 13:52:52 GMT

Same as Xia:

data have;

input id $ spend;

cards;

1 100

1 200

1 300

2 150

2 690

;

data want(drop=count spend);

set have ;

by id;

array mon(3) jan feb march;

retain mon;

if first.id then do;

call missing(of mon{*});

count=0;

end;

count+1;

mon(count)= spend;

if last.id then output;

run;

Thanks,

Naveen Srinivasan

L&T infotech