topic Re: How to split a dataset by each row in SAS Programming

How to split a dataset by each row

spirto — Tue, 12 Aug 2014 19:56:04 GMT

Hello I have the following dataset format:

R1	R2	R3	R4	R5
A	B	C	D	E
F	G	H	I	J
K	L	M	N	O
P	Q	R	S	T
...	...	...	...	...

and I would like to create 4 new datasets photo1, photo2, photo3, photo4, etc:

R1	R2	R3	R4	R5
A	B	C	D	E

R1	R2	R3	R4	R5
F	G	H	I	J

etc. I am not sure if this can be done using a BY statement some how or maybe through a proc append, etc. Any suggestions?

Re: How to split a dataset by each row

Reeza — Tue, 12 Aug 2014 20:00:31 GMT

There's many ways, but I have to ask why, there's almost always a better way to deal with this situation.

Split Data into Subsets - sasCommunity

Re: How to split a dataset by each row

Reeza — Tue, 12 Aug 2014 20:58:49 GMT

Here's an example that splits the CLASS file into one row per file.

It assumes that each file is for each name. Your exact code will vary by how you want to split the file.

data _null_;

set sashelp.class;

by name notsorted;

if first.name then do;

call execute("data row"||put(_n_,z2.)||"; set sashelp.class(where=(name='"||name||"'));run;");

end;

run;

Re: How to split a dataset by each row

stat_sas — Tue, 12 Aug 2014 21:01:09 GMT

data have;
input R1 $ R2 $ R3 $ R4 $ R5 $;
CNT+1;
datalines;
A B C D E
F G H I J
K L M N O
P Q R S T
;

proc sql;
select max(cnt) into :cnt from have;
quit;
%macro sets;
data
%do i=1 %to &cnt;
photo&i
%end;
;

set have(drop=cnt);

if _n_=1 then output photo1;
%do i = 2 %to &cnt;
else if _n_=&i then output photo&i;
%end;
run;
%mend sets;
%sets

Re: How to split a dataset by each row

spirto — Wed, 13 Aug 2014 01:43:49 GMT

Thank you both!

Re: How to split a dataset by each row

Ksharp — Wed, 13 Aug 2014 13:08:10 GMT

The fastest way is using Hash Table.




data _null_;
 if _n_ eq 1 then do;
  if 0 then set sashelp.class;
  declare hash h();
   h.definekey('n');
   h.definedata('name','age','weight','height');
   h.definedone();
end;
set sashelp.class;
n+1;h.add();h.output(dataset: cats('_',n)); h.clear();
run;

Xia Keshan