topic Re: want to add a date to my ODS HTML text in SAS Programming

want to add a date to my ODS HTML text

Filipvdr — Wed, 02 Mar 2011 11:14:24 GMT

%global datim = datetime();
%put &datim;
ods html file="/imec/other/imecweb/osp/fab300/test/shift_reports/PrioLotReport.html" (title="Prio Lot Report") stylesheet=(URL="http://imecwww.imec.be/~osp/fab300/test/ImecStyle.css");
ods listing close;
ods escapechar='^';
/* title */
ods html text='^S={just=c font_size=15pt foreground=black} Prio Lot Report - Last Run on &datim ^S={}';

but &datim shows as &datim, any solutions?

Re: want to add a date to my ODS HTML text

Tim_SAS — Wed, 02 Mar 2011 13:20:42 GMT

Enclose the text in quotes instead of apostrophes. SAS does not resolve macro variables within apostrophes.

Re: want to add a date to my ODS HTML text

Andre — Wed, 02 Mar 2011 13:41:25 GMT

Apparently more unclear Tim

[pre]
%global datim= %sysfunc(compress(%sysfunc(datetime(),IS8601DT.), -:));
%global dati = datetime();
%put &datim;%put &dati;
ods listing close;
ods html file="d:\temp\PrioLotReport.html" (title="Prio Lot Report") ;
ods escapechar='^';
/* title */
*ods html text="^S={just=c font_size=15pt foreground=black} Prio Lot Report - Last Run on &datim &dati ^S={}";
ods html text="Prior Lot Report - Last Run on %sysfunc(datetime()) &sysdate
&datim &dati ";
proc print data=sashelp.class(obs=1);run;
ods html close;

[/pre]

Is it more specifically a problem of how the ods clothing is working and
WHEN is it passing the chain to the ods construct ?

In my test the direct datetime and sysdate are resolved but not the macros variables

Andre

Re: want to add a date to my ODS HTML text

Tim_SAS — Wed, 02 Mar 2011 17:01:14 GMT

The ODS statement is no different than any other statement. The macro processor runs before the ODS statement is executed. The ODS statement gets the text that the macro processor produced. I ran your test:

[pre]
%global datim;
%let datim = %sysfunc(compress(%sysfunc(datetime(),IS8601DT.), -:));
%global dati;
%let dati = datetime();
%put &datim;%put &dati;
ods listing close;
ods html file="PrioLotReport.html" (title="Prio Lot Report") ;
ods escapechar='^';
/* title */
*ods html text="^S={just=c font_size=15pt foreground=black} Prio Lot Report - Last Run on &datim &dati ^S={}";
ods html text="Prior Lot Report - Last Run on %sysfunc(datetime()) &sysdate &datim &dati ";
proc print data=sashelp.class(obs=1);run;
ods html close;
[/pre]

The text in the HTML file is:
Prior Lot Report - Last Run on 1614686110.021 02MAR11 20110302T115509 datetime()

Re: want to add a date to my ODS HTML text

Andre — Wed, 02 Mar 2011 17:20:15 GMT

You are right, Tim
I think i was perhaps opening the wrong html file on my pc without reading carefully the log.
In fact rereading the code
i reproduce the problem i have encounter
when based too quickly upon the initial %global statement
i did not apply the correct syntax
%global datim; for defining the status of a macro variable
and then only after
%let datim=
with the definition of the content.
%global datim= genders errors in the log
Sorry
Andre Message was edited by: Andre

Re: want to add a date to my ODS HTML text

Filipvdr — Fri, 04 Mar 2011 07:48:16 GMT

thanks, it is working

Re: want to add a date to my ODS HTML text

Peter_C — Sat, 05 Mar 2011 16:39:31 GMT

> %global datim = datetime();

is this expecting %global to assign a value?
sorry, it doesn't work that way.
the above syntax generates an ERROR: pointing to the '=' in my SAS9.2

you need %LET datim = something ;