topic Re: Issue in SAS while trying to create a macro. in SAS Programming

Issue in SAS while trying to create a macro.

Vimal_SAS — Tue, 23 Sep 2014 16:10:47 GMT

*** Test macro ***;

%macro test;

%if (%sysevalf(&a*1) <= %sysevalf(&b*1)) %then %do;

%put %sysevalf(&a*1) IS LESS THAN OR EQUAL TO %sysevalf(&b*1);

%end;

%else %do;

%put %sysevalf(&a*1) GREATER THAN %sysevalf(&b*1);

%end;

%mend test;

%let a=10.6;

%let b=9.9;

%test;

%let a=9.9;

%let b=10.6;

%test;

These two macro calls give me a wrong answer. Can anyone help me out from this?

Re: Issue in SAS while trying to create a macro.

Reeza — Tue, 23 Sep 2014 16:15:07 GMT

Your comparison is also a function, so add one more %sysevalf:

%macro test;

%if (%sysevalf(%sysevalf(&a*1) <= %sysevalf(&b*1))) %then %do;

%put %sysevalf(&a*1) IS LESS THAN OR EQUAL TO %sysevalf(&b*1);

%end;

%else %do;

%put %sysevalf(&a*1) GREATER THAN %sysevalf(&b*1);

%end;

%mend test;

%let a=10.6;

%let b=9.9;

%test;

%let a=9.9;

%let b=10.6;

%test;

Re: Issue in SAS while trying to create a macro.

data_null__ — Tue, 23 Sep 2014 16:32:23 GMT

Actually you have too many %SYSEVALs

%macro test; 
   %let rc = %sysevalf(&a*1 <= &b*1,boolean);
   %put NOTE: &=rc;
   %let tf = %scan(False True,%eval(&rc+1));
   %put NOTE: Expression &a*1 <= &b*1 is &tf;
   %mend test;
 
%let a=10.6;
%let b=9.9;
%test; 
 
%let a=9.9;
%let b=10.6;
%test; 

40         %let a=10.6; 
41         %let b=9.9; 
42         %test; 
NOTE: RC=0
NOTE: Expression 10.6*1 <= 9.9*1 is False
43         
44         %let a=9.9; 
45         %let b=10.6; 
46         %test; 
NOTE: RC=1
NOTE: Expression 9.9*1 <= 10.6*1 is True

Re: Issue in SAS while trying to create a macro.

Astounding — Tue, 23 Sep 2014 17:13:59 GMT

Also note, once you have the proper number of %sysevalf functions, you do not need to multiply by 1.

%if 9.9 < 10.6 is false because decimal points force a character comparison, but

%if %syseval(9.9 < 10.6) returns 1, a true comparison.

Re: Issue in SAS while trying to create a macro.

data_null__ — Tue, 23 Sep 2014 19:57:08 GMT

I'n not the one who wrote the expression. I don't care if the OP multiplies by 1 or not.