topic Re: How to delete series of observations in SAS Programming

How to delete series of observations

Kristinos — Thu, 16 Oct 2014 06:34:49 GMT

Hi,

I want to delete all ID's that doesn't have observations after 4 years of age. How could I do that?

Data1:

id age obs

10 8 100

10 9 192

10 6 90

10 3 80

20 1 10

20 3 30

20 2 40

30 4 60

30 8 100

30 5 30

40 1 40

40 2 45

This is what I want (ID 20 and 40 are deleted):

ID age obs

10 8 100

10 9 192

10 6 90

10 3 80

30 4 60

30 8 100

30 5 30

Thanks

Re: How to delete series of observations

arodriguez — Thu, 16 Oct 2014 08:00:58 GMT

Maybe not is the easier solution but I would do something like

proc sql norprint;

create table maxage as(

select ID, max(age) as max_age

from dataset

group by id

);

quit;

Doing this, you will get a dataset with

ID Max_age

10 9

20 3

30 8

40 2

Then I will merge with the original data and keep all that have max_age greater than 4 with a if or where condition

Re: How to delete series of observations

Loko — Thu, 16 Oct 2014 09:30:41 GMT

Hello,

data have;
input id age obs;
datalines;
10 8 100
10 9 192
10 6 90
10 3 80
20 1 10
20 3 30
20 2 40
30 4 60
30 8 100
30 5 30
40 1 40
40 2 45
;

data want;
merge have (in=a) have (in=b where=(dropage gt 4) rename=(age=dropage));
by id;
if a and b;
drop dropage;
run;

Re: How to delete series of observations

RW9 — Thu, 16 Oct 2014 09:48:40 GMT

Simple sub-query:

proc sql;

create table WANT as

select *

from WORK.HAVE

where ID in (select distinct ID from WORK.HAVE where AGE >= 4);

quit;

Re: How to delete series of observations

stat_sas — Thu, 16 Oct 2014 11:55:40 GMT

proc sql;

create table want as

select * from have

group by id

having sum(age>=4);

quit;

Re: How to delete series of observations

Kristinos — Thu, 16 Oct 2014 12:24:52 GMT

Thank you for all the good ideas!!!

VERY helpful!