topic Re: How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation? in SAS Programming

How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation?

MrBruce — Tue, 15 Jul 2014 20:33:02 GMT

Suppose the 'Grade' variable has 100 observations. I want to calculate the mean of those 100 observations and save the value as one varaible on the table. I know we could easily get the mean through "proc mean", but that will not save the mean value as a new varaible on the same table.

Thanks in advance.

Re: How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation?

Reeza — Tue, 15 Jul 2014 20:37:01 GMT

Here's a SQL option:

proc sql;

create table want as

select *, mean(age) as avg_age

from sashelp.class;

quit;

Re: How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation?

stat_sas — Tue, 15 Jul 2014 20:43:46 GMT

data have;

input grade;

datalines;

1.4

3.2

3.4

2.1

4.3

5.4

;

proc sql;

select grade,avg(grade) as mean from have;

quit;

Re: How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation?

Ksharp — Wed, 16 Jul 2014 12:37:27 GMT

OR, after get mean by proc mean , you can do something like this:

proc mean noprint;

......

output out=mean mean=;

run;

data want;

set have;

if _n_ eq 1 then set mean;

run;

Xia Keshan

Re: How to calculate the mean of all the observations of one variable and add the mean value as a variable on the table for every observation?

user24feb — Wed, 10 Dec 2014 13:55:07 GMT

As an alternative you could loop through your data set yourself and add the mean:

data have;
input grade;
datalines;
1.4
3.2
3.4
2.1
4.3
5.4
;
Run;

Data Want (Drop=Obs i Total);
Do Obs=1 By 1 Until (Eof);
Set Have End=Eof;
Total=Sum(Total,Grade);
End;
Mean=Total/Obs;
Do i=1 To Obs;
Set Have;
Output;
End;
Run;