topic Re: Help in SAS Programming

Help

manjo — Sat, 12 Apr 2014 17:00:28 GMT

Hi all; Thanks in advance for your answers

My question is

how to choose the rows where eid occurring more than once?

data abc;

input eid name$ age;

cards;

100 ppp 26

100 ppp 25

101 qqq 32

102 qqw 31

102 qqq 32

104 yyy 53

102 xxx 51

;

Re: Help

PGStats — Sat, 12 Apr 2014 17:26:56 GMT

proc sql;

select * from abc group by eid having count(*)>1;

quit;

Re: Help

manjo — Sat, 12 Apr 2014 18:17:21 GMT

Thank you

PGStats

Re: Help

WWW_BIGINFOANALYSIS_COM — Sat, 12 Apr 2014 18:32:11 GMT

proc sort data=abc;

by eid;

run;

data abc1 eid(keep=eid);

set abc;

by eid;

if first.eid=1 then count=0;

count+1;

if _N_ <> 1 and count>1 then output eid;

run;

proc sort data=eid nodupkey;

by eid;

run;

data abc_op;

merge abc(in=a) eid(in=b);

by eid;

if a=1 and b=1;

run;

Any other simple solutions of doing this in a data step ?

http://www.biginfoanalysis.com

Re: Help

PGStats — Sat, 12 Apr 2014 19:08:39 GMT

Sure.

proc sort data=abc; by eid; run;

data want;

set abc; by eid;

if not (first.eid and last.eid);

run;

proc print data=want noobs; run;

Re: Help

Ksharp — Sun, 13 Apr 2014 02:41:47 GMT

data step version solution.

data abc;
input eid name$ age;
cards;
100 ppp 26
100 ppp 26
100 ppp 25
101 qqq 32
102 qqw 31
102 qqq 32
104 yyy 53
102 xxx 51
;
run;
proc sort data=abc;by eid;run;
data want;
 set abc;
 by eid;
 if not (first.eid and last.eid);
run;

Xia Keshan