topic Re: sentence case in SAS Programming

sentence case

VRD — Wed, 17 Dec 2014 09:49:22 GMT

I want to make sentence case through out my variables.

For ex: in 3 parts of my paper there are remarks. please go through them.

This should become like this

In 3 parts of my paper there are remarks. Please go through them.

How can this be done.

Re: sentence case

Patrick — Wed, 17 Dec 2014 10:23:58 GMT

One way to go:

data _null_;

have='in 3 parts of my paper there are remarks. Have you read them? please go through them! then send it back to me.';

want=prxchange('s/(^ *.)|([\.\?!] +.)/\U\1\2\E/oi',-1,have);

put want=;

run;

Re: sentence case

Loko — Wed, 17 Dec 2014 10:37:51 GMT

Hello,

Another one:

data _null_;

length y $ 50;

x="in 3 parts of my paper there are remarks. please go through them.";

i+1;

do until(scan(x,i,".") eq "");

y=cats(upcase(substr(left(scan(x,i,".")),1,1)),substr(left(scan(x,i,".")),2));

x=left(tranwrd(x,scan(x,i,"."),cat(" ",strip(y))));

i+1;

put x= ;

end;

run;

Re: sentence case

VRD — Wed, 17 Dec 2014 10:47:25 GMT

unfortunately they are not working

Re: sentence case

andreas_lds — Wed, 17 Dec 2014 10:54:21 GMT

Tried the prxchange solution provided by Patrick, and the output was:

want=In 3 parts of my paper there are remarks. Have you read them? Please go through them! Then send it back to me.

Please explain what does not work.

Re: sentence case

VRD — Wed, 17 Dec 2014 10:59:38 GMT

i do not have any other signs other than .(full stop).

will it still work because i am getting all in upcase after using patricks code

Re: sentence case

Loko — Wed, 17 Dec 2014 11:27:55 GMT

hello,

what do you mean by "not working" ? the output is:

x=In 3 parts of my paper there are remarks. Please go through them.

Re: sentence case

Kurt_Bremser — Wed, 17 Dec 2014 11:36:51 GMT

You must have made an error in copying the code. here's my log:

16 data _null_;

17 have='in 3 parts of my paper there are remarks. Have you read them. please go through them. then send it back to me.';

18 want=prxchange('s/(^ *.)|([\.\?!] +.)/\U\1\2\E/oi',-1,have);

19 put want=;

20 run;

want=In 3 parts of my paper there are remarks. Have you read them. Please go through them. Then send it back to me.

Re: sentence case

Ksharp — Wed, 17 Dec 2014 12:13:39 GMT

Patrick

Your Perl Regular Expression is more and more better now . Are you working on it for a long time ?

BTW, \1\2\ stand for what ?

Xia Keshan

Re: sentence case

Ksharp — Wed, 17 Dec 2014 12:37:30 GMT

Here is another way other than Perl.

data _null_;

have='in 3 parts of my paper there are remarks. Have you read them? please go through them! then send it back to me.';

length want temp punc $ 200;

punc=compress(have,'.?!','k');

do i=1 to countw(have,'.?!') ;

temp=strip(scan(have,i,'.?!')); put temp=;

substr(temp,1,1)=upcase(substr(temp,1,1)) ;

want=cats(want,temp,substr(punc,i,1));

end;

put want=;

run;

Xia Keshan

Re: sentence case

Ksharp — Wed, 17 Dec 2014 12:56:51 GMT

Here is my PRX.

data _null_;

have='in 3 parts of my paper there are remarks. Have you read them? please go through them! then send it back to me.';

want=prxchange('s/((^\s*\w)|(?<=\.|\?|!)(\s*\w))/\U$1\E/',-1,have);

put want=;

run;

Xia Keshan

Re: sentence case

VRD — Wed, 17 Dec 2014 13:14:30 GMT

Hi all,

I somehow cant get it cracked as for my variable i still get few observations with upcase

ex: SMALL PARTICLES IN THE RESERVOIR, APPEAR TO BE SILICONE PARTICLES

is it because there is no comma or full stop which is not working in this case

Re: sentence case

Ksharp — Wed, 17 Dec 2014 15:55:39 GMT

I really suggest you to post some real data of yours . Let's where is the problem.

Re: sentence case

art297 — Wed, 17 Dec 2014 16:08:05 GMT

Is your problem that the variable first has to be converted to be lower case? e.g., using ksharp's code:

data want;

informat have $150.;

format have want $150.;

input have &;

want=prxchange('s/((^\s*\w)|(?<=\.|\?|!)(\s*\w))/\U$1\E/',-1,lowcase(have));

cards;

in 3 parts of my paper there are remarks. Have you read them? please go through them! then send it back to me.

SMALL PARTICLES IN THE RESERVOIR, APPEAR TO BE SILICONE PARTICLES

run;

Re: sentence case

Haikuo — Wed, 17 Dec 2014 18:47:06 GMT

To refer first and second buffer. Same as using $1$2.

Re: sentence case

Haikuo — Wed, 17 Dec 2014 18:53:50 GMT

Is it possible that your incoming data are all CAPPED for your particular records?

Re: sentence case

Patrick — Wed, 17 Dec 2014 21:58:28 GMT

Thanks . And no, didn't take me that long.

Amending this based on 's explanation:

I love the power of regular expressions even though the syntax is "cryptic" and I have still almost always to consult the metacharacter page SAS(R) 9.4 Functions and CALL Routines: Reference, Third Edition to get it right.

In real life implementations I don't have that many cases where I use regular expressions - but if I have such a case then using regular expressions makes a difference. Most of the time it's related to data cleansing tasks.

Re: sentence case

Haikuo — Wed, 17 Dec 2014 22:19:50 GMT

Being as same Chinese as , Please allow me to interpret what he really means :

Are you working on it for a long time ? = Are you using PRX a lot?

Haikuo