topic Re: Create quoted flat file headers in SAS Programming

Create quoted flat file headers

Jaheuk — Tue, 16 Dec 2014 10:47:13 GMT

Dear all,

I finally discovered that using a tilde put quotes around the values.

Perfect!!

Now I still what quotes around the headers.

I can use the quote function in the query quote(trim(name)) . . and yes quotes are added but the PUT statement still
fails in the data _null_ step.

Suggestions???

proc sql noprint;
select trim(name) into :vars separated by ';'
from dictionary.columns
where libname="SASHELP" & memname="CLASS"
order by varnum ;
quit;

filename temp 'c:\temp\test.txt' ;

data _null_;
file temp dlm=";" dsd lrecl=3000;
put "&vars." ;
do until (eof);
set SASHELP.CLASS end=eof;
put (_all_)(~);
end;
stop;
run;

GreetZ,

Herman

Re: Create quoted flat file headers

RW9 — Tue, 16 Dec 2014 11:18:06 GMT

Well, I am sure there is a better way, however you can generate the necessary code rather than using a macro variable, something like:

filename temp 's:\temp\rob\test.txt' ;

data temp;
set sashelp.vcolumn (where=(libname="SASHELP" and memname="CLASS")) end=last;
length lst_list $2000.;
retain lst_list;
if _n_=1 then lst_list='"'||strip(name)||'";';
else lst_list=strip(lst_list)||'"'||strip(name)||'";';
if last then do;
    call execute('data _null_; file temp dlm=";" dsd lrecl=3000; set sashelp.class;');
    call execute(" put '"||strip(lst_list)||"';");
    call execute('; put (_all_)(~); run;');
end;
run;

Re: Create quoted flat file headers

data_null__ — Tue, 16 Dec 2014 12:47:06 GMT

You need to make the syntax correct by doubling the double quotes inside the quoted string in the PUT statement. Use the QUOTE function again on VARS.

proc sql noprint; 
   select quote(trim(name)) into :vars separated by ';' 
   from dictionary.columns where libname="SASHELP"    & memname="CLASS" order by varnum ; 
   quit; 
%put NOTE: %superq(vars); 
 
filename temp temp;*'c:\temp\test.txt' ;
data _null_; 
   file temp dlm=";" dsd lrecl=3000; 
   put %sysfunc(quote(%superq(vars)));
   do until (eof);
      set SASHELP.CLASS end=eof;
      put (_all_)(~);
      end; 
   stop; 
   run; 
data _null_; 
   infile temp; 
   input; 
   put _infile_; 
   run;

Re: Create quoted flat file headers

Ksharp — Wed, 17 Dec 2014 15:34:03 GMT

Why not use ods csv ?

ods csvall file='c:\temp\x.csv' options(doc="help" Delimiter=';' Quoted_columns="123456789");
 title ' ';
 proc print data=sashelp.class noobs;run;
ods csvall close;

Xia Keshan