topic Re: extracting the date using the datepart function?? in SAS Programming

extracting the date using the datepart function??

koushik — Wed, 29 Oct 2014 10:15:51 GMT

hello community,

in the question data set i have date in as "13may2005:00:00:00. It is in the character type. could some one help me how do i extract the date from this using the datepart?? i am new to sas.

thanks for your help

Re: extracting the date using the datepart function??

Kurt_Bremser — Wed, 29 Oct 2014 10:23:18 GMT

newdate=datepart(input(olddate,datetime18.));

ie:

data _null_;

olddate = "13may2005:00:00:00";

format newdate date9.;

newdate=datepart(input(olddate,datetime18.));

put newdate=;

run;

Re: extracting the date using the datepart function??

koushik — Wed, 29 Oct 2014 11:46:18 GMT

hello,

thanks for the replay. In my question i have multiple rows.it looks like this

race_date

12may2005:00:00:00

04sep2006:00:00:00

27jan2005:00:00:00

and all i need is to create a new column(new_race_date) in which the date from the column(race_date) is extracted!!

thanks for your support!!

koushik.

Re: extracting the date using the datepart function??

RW9 — Wed, 29 Oct 2014 11:50:13 GMT

So race_date is a character yes? And you want new_race_date to also be a character yes?

If so then:

data xyx;

set xyx;

new_race_date=scan(race_date,1,':');

run;

If you want new_race_date to be numeric then:

new_race_date=input(scan(race_date,1,':'),date9.);

If race_date is already numeric and you want numeric then:

new_race_date=datepart(race_date);

And for numeric race_date to character new_race_date:

new_race_date=put(datepart(race_date);

Re: extracting the date using the datepart function??

Kurt_Bremser — Wed, 29 Oct 2014 12:07:15 GMT

You just need to insert your variable names in my example. Can't be that complicated, no?

If it does not work, post the log.

Re: extracting the date using the datepart function??

stat_sas — Wed, 29 Oct 2014 12:10:54 GMT

data have;

input race_date $20.;

format new_race_date date9.;

new_race_date=input(race_date,date9.);

datalines;

12may2005:00:00:00

04sep2006:00:00:00

27jan2005:00:00:00

;

Re: extracting the date using the datepart function??

Haikuo — Wed, 29 Oct 2014 13:56:07 GMT

Slick!

Re: extracting the date using the datepart function??

Malv72 — Thu, 30 Oct 2014 16:16:50 GMT

It seems you should be most if not all the way there.

For me there are two main ways you can use with the date being in a string, firstly input and date part, and secndly substring and input.

Here is some code demonstrating what i mean.

data source_ds;

input race_date $20.;

datalines;

12may2005:00:00:00

04sep2006:00:00:00

27jan2005:00:00:00

;

run;

data target_ds;

set source_ds;

format new_race_date date9.;

/* date part method */

new_race_date=datepart(input(race_date,datetime18.));

/* substring method */

new_race_date=input(substr(race_date,1,9),date9.);

run;

Re: extracting the date using the datepart function??

koushik — Thu, 30 Oct 2014 17:12:35 GMT

hello,

wow..... really thanks a lot for your support... this worked like a magic..................this is very simple and easy....

you rockkk!!!!!

Re: extracting the date using the datepart function??

koushik — Thu, 30 Oct 2014 17:14:54 GMT

hi all,

thanks for investing your time... you guys are very helpful!!!!

thanks a lot to all............