topic Re: Extracting substring using scan or any function in SAS Programming

Extracting substring using scan or any function

kishore415 — Wed, 22 Jun 2011 10:34:19 GMT

Hi All..

I want to extract the substring from a string till the last occurrence of my delimiter, for example a dataset has values a below..

str
A
A,B
A,B,C
A,B,C,D

I want to extract the substring till the last occurence of ',' in the above dataset.the resultant dataset should look like ...

str
A
A
A,B
A,B,C

Thanks in advance..

Re: Extracting substring using scan or any function

GertNissen — Wed, 22 Jun 2011 11:40:56 GMT

Two way of doing it...

[pre]
data input;
input str $;
datalines;
A
A,B
A,B,C
A,B,C,D
;
run;

data extract1(drop=_str_length _i _comma_pos);
set input;
_str_length = length(str);
do _i = 1 to _str_length;
if substr(str,_i,1) = ',' then _comma_pos=_i-1;
end;
ext=substr(str,1,max(_comma_pos,1));
output;
run;

data extract2(drop=_last_element);
set input;
_last_element=scan(str,-1);
ext=tranwrd(str,cats(',',_last_element),'');
run;
[/pre]

Re: Extracting substring using scan or any function

ballardw — Wed, 22 Jun 2011 18:12:59 GMT

SCAN may be better for your approach. You can specify a list of delimiters if something other than the defaults and to search backwards, the -1 says start at the end and find the first "word" counting backwards.

result= scan(str,-1);

Re: Extracting substring using scan or any function

Patrick — Mon, 07 Aug 2017 15:30:12 GMT

Just another variation:

data input; 
input str $; 
datalines;
A
A,B
A,B,C
A,B,C,D
;
run;

data want;
 set input;
 SubStrLength=findc(str, ',',-length(str)) ;
 if SubStrLength=0 then WantStr=Str;
  else WantStr=substr(str,1,SubStrLength-1);
 drop SubStrLength;
run;

proc print;
run;

And this from @cidab:

data  input;
 input str $;
 want = substr(str,1,length(str)-indexc(reverse(trim(str)),','));    
...
**trim the input string, reverse it and find the position of last (now first) comma, then substring input string from start to string length minus the number of characters to drop;

Re: Extracting substring using scan or any function

kishore415 — Thu, 23 Jun 2011 03:51:14 GMT

Dear ballardw

scan with -1 will give last word but I want remaining words excepting last word.... Message was edited by: kishore415

Re: Extracting substring using scan or any function

kishore415 — Thu, 23 Jun 2011 03:55:01 GMT

Dear Patrick...

Your code looks simple and works..thanks a lot...

Re: Extracting substring using scan or any function

Ksharp — Thu, 23 Jun 2011 09:58:35 GMT

[pre]

data input;
input str $20.;
position=findc(str,',','b');
if position=0 then want=str;
else want=substr(str,1,position-1);
datalines;
A
A,Brertyr
A,B,Ce
A,B,C,Ddsd
;
run;
[/pre]

Ksharp

Re: Extracting substring using scan or any function

cidab — Fri, 24 Jun 2011 17:24:45 GMT

data input;
input str $;
want = substr(str,1,length(str)-indexc(reverse(trim(str)),','));
**trim the input string, reverse it and find the position of last (now first) comma, then substring input string from start to string length minus the number of characters to drop;

Re: Extracting substring using scan or any function

NathanOch — Wed, 14 Sep 2016 20:10:01 GMT

cidab has a great solution. I've used this a couple times now to only extract what I need from a string.

Nathan Och

Re: Extracting substring using scan or any function

arpi — Sat, 09 Dec 2017 20:20:55 GMT

data input_extract;
set input;

len = length(str);

do i =1 to len;
len1 = len -2;
sub_str = substr(str,1,len1);
end;
run;