topic Re: Need explantion why these lines of code does not work. in SAS Programming

Need explantion why these lines of code does not work.

dtchoi86 — Thu, 29 Jan 2015 14:36:18 GMT

I need help understanding why nwords will not resolve in the following lines of code:

%let drug=EXAMPLEONE, EXAMPLETWO;

%macro test;

Data test;

drugs="&drug";

dm = ',';

mod = 'oq';

nwords = countw(drugs, dm, mod);

call symput('nwords',nwords);

%do i=1 %to &nwords;

drug&i=strip(scan(drugs, &i, dm, mod));

%end;

run;

%mend test;

%test;

However this works:

%macro test;

Data _null_;

drugs="&drug";

dm = ',';

mod = 'oq';

nwords = countw(drugs, dm, mod);

call symput('nwords',nwords);

run;

data test;

drugs="&drug";

dm = ',';

mod = 'oq';

nwords = countw(drugs, dm, mod);

%do i=1 %to &nwords;

drug&i=strip(scan(drugs, &i, dm, mod));

%end;

run;

%mend test;

%test;

Thank you in advance!

Re: Need explantion why these lines of code does not work.

RW9 — Thu, 29 Jan 2015 14:56:03 GMT

You are mixing up macro code and datastep code is the reason:

So, your macro test. When it is called it will expand all the macro code into useable SAS code, then send that to the compiler. So your call to symput doesn't get actioned until *after* all the macro has been evaluated, hence %do I=1 to &Nwords will result in a problem as nwords is not defined. What are you attempting to do, as from the code above there is no reason to resort to macro code anyway.

Data test;

drugs="&drug"; /* Don't know where this comes from? */

dm = ',';

mod = 'oq';

array drug{100} $200.; /* I am just assuming no more than 100 */

do i=1 to countw(drugs, dm, mod);

drug{I}=strip(scan(drugs,i,dm,mod));

end;

run;

Re: Need explantion why these lines of code does not work.

dtchoi86 — Thu, 29 Jan 2015 17:30:04 GMT

Thank you so much for your explanation. It was very informative and helpful. If it is not too much, could you explain why the following does not work as well:

%macro test

Data test (drop=drugs dm mod nwords);

drugs="&drug";

dm = ',';

mod = 'oq';

nwords = countw(drugs, dm, mod);

%do i=1 %to nwords;

drug&i=strip(scan(drugs, &i, dm, mod));

%end;

run;

%mend test;

;

%test

Is this because, similar as your explanation for my previous question, there is a mismatch with data step code and macro code?

Re: Need explantion why these lines of code does not work.

RW9 — Thu, 29 Jan 2015 18:51:11 GMT

Thats correct. In step one your macro parts are expanded/resolved, as at that point nwords has not been created it fails. So think of it this way, when the macro-preprocessor works it is trying to create a full base SAS program with nothing macro left in. That code is then passed onto the compiler to be actioned. So nwords is part of the datastep in the second step, but you are trying to reference it in macro language in step 1.