topic Macro Variable in SAS Programming

Macro Variable

petlove — Mon, 16 Jul 2018 22:12:08 GMT

Hi,

I am trying to create macro variable which will have string as below:

"%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)"

: %varexist is macro in my directory which finds if variable exist in specified dataset. Var1 and var2 are present in another macro varibale "&variables" macro variable.

e.g. %put &variables= &dsn.var1, &dsn.var2;

In order to get above mentioned string, I am creating variable varcond like below for each variables and then concatenating them together :

data _temp_;
%do i =1 %to %sysfunc(countw(&variables.));
%let var=%scan(&variables.,&i);
varcond= "%"||"varexist(sdtmcro.&dsn,&var)";
output;
%end;
domain="&dsn";
run;

proc sort data=_temp_;
by domain ;
run;

data _temp_;
length varcondn $500.;
do until(last.domain );
set _temp_;
by domain ;
condn=catx(' and ',cond,varcond);
end;
run;

proc sql;
select condn into : condition
from _temp_;
quit;

%put &condition;

&condition gets resolved string "1 and 1" instead of "%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)".

Can anyone suggest me solution on not resolve macro %varexist in macro variable &condition?

Re: Macro Variable

PaigeMiller — Mon, 16 Jul 2018 22:22:25 GMT

Re-run your code, but first issue the command

options mprint;

Then, show us the SASLOG so we can see the error.

Re: Macro Variable

petlove — Mon, 16 Jul 2018 22:33:51 GMT

There is no error in log.

I am expecting to get &condition resolved to

"%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)"

But, it is getting resolved to : "1 and 1"

Thank you.

Re: Macro Variable

PaigeMiller — Mon, 16 Jul 2018 22:38:56 GMT

How can we possibly help, if you won't show us the SASLOG, and we don't have the code to see what %varexist does?

Run the code again, turn on these options

options mprint symbolgen mlogic;

and show us the SASLOG.

Re: Macro Variable

Astounding — Mon, 16 Jul 2018 22:48:43 GMT

The %PUT statement causes the macro calls to %VAREXIST to execute. Try either of these instead:

%put %superq(condition);

%put _user_; /* this might give you a bit more than what you want to see */

Re: Macro Variable

petlove — Mon, 16 Jul 2018 22:53:52 GMT

Here is the log file

Re: Macro Variable

PaigeMiller — Mon, 16 Jul 2018 23:49:53 GMT

There no %varexist macro anywhere in your log. And what is the %varcond macro shown in the log? Whatever this is, it doesn't relate to your original question.

Also, turn on the options as the first line of your program.

Re: Macro Variable

Tom — Tue, 17 Jul 2018 02:01:53 GMT

If you want to see the macro variables contents without the macro processor evaluating the macro calls then you need to use macro quoting to prevent it.

Try:

%put %superq(condition);

Or look at it using normal SAS code.

data _null_;
  condition=symget('condition');
  put condition=;
run;

Re: Macro Variable

petlove — Tue, 17 Jul 2018 02:56:09 GMT

Thank you Tom for your response.

I tried first option you provided. Now, I see "%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)" in log or in program where I recall it.

I am having one more trouble.

In my other program, I am calling this %varcond in %if condition as follow:

%if %varcond(&dsn) %then %do;

proc sort data=sdtmcro.&dsn out=&dsn;
by usubjid ;
run;

%end;

But, I get following error:

ERROR: Required operator not found in expression: %varcond(&dsn)
MLOGIC(VARCOND): %PUT %superq(varcondn)
WARNING: Apparent symbolic reference VARCONDN not resolved.

I expect to run do loop by checking this condition:

%if %varcond %then %do= %if %varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2) %then %do

Please let me know what would resolve this problem.

Re: Macro Variable

ChrisNZ — Tue, 17 Jul 2018 02:59:43 GMT

Like this?

data _temp_;
domain="&dsn";
%do i =1 %to %sysfunc(countw(&variables.));
%let var=%scan(&variables.,&i);
varcond= "%"||"varexist(sdtmcro.&dsn,&var)";
output;
%end;
run;
 
data _TEMP2_;
  length CONDN $500;
  retain CONDN;
  set _TEMP_;
  CONDN=catx(' and ',CONDN, VARCOND);
  call symputx('condition', CONDN);
run;

%put => %superq(condition);

=> %varexist(sdtmcro.&dsn,&var) and %varexist(sdtmcro.&dsn,&var)

You don't need by group processing in your example as variable DOMAIN is a constant;

Re: Macro Variable

Tom — Tue, 17 Jul 2018 04:08:16 GMT

In my other program, I am calling this %varcond in %if condition as follow:

%if %varcond(&dsn) %then %do;

proc sort data=sdtmcro.&dsn out=&dsn;
by usubjid ;
run;

%end;

But, I get following error:

ERROR: Required operator not found in expression: %varcond(&dsn)
MLOGIC(VARCOND): %PUT %superq(varcondn)
WARNING: Apparent symbolic reference VARCONDN not resolved.

Looks like you have a bug in the macro %VARCOND().

The error message says that you are referencing a macro variable named VARCONDN that has not been defined.

Perhaps it is just a typo? Is there perhaps a macro variable named VARCOND and you accidentally added an extra N in the %superq() macro function call?

Re: Macro Variable

petlove — Tue, 17 Jul 2018 14:49:28 GMT

Thank you Tom. I made respective changes in my program.

When I recall macro in following way, there is no error.

%varcond(LB);

MLOGIC(VARCOND): %PUT %superq(varcond)
%varexist(sdtmcro.LB,LBSTRESC) and %varexist(sdtmcro.LB,LBDRVFL)

However, when I write it in %if condition, I still see this error where "%PUT %superq(varcond)" is blank:

%if %varcond(LB) %then %do;

proc sort data=sdtmcro.&dsn out=&dsn;
by usubjid ;
run;

%end;

LOG:

SYMBOLGEN: Macro variable DSN resolves to LB
ERROR: Required operator not found in expression: %varcond(&dsn)
MLOGIC(VARCOND): %PUT %superq(varcond)

Thank you.

Re: Macro Variable

Tom — Tue, 17 Jul 2018 14:58:53 GMT

Possibly because of a missing semi-colon?

That could cause the %PUT statement to be waiting for the closing semi-colon so that the %SUPERQ() function does not actually run until after the macro has finished executing?

Re: Macro Variable

petlove — Tue, 17 Jul 2018 15:11:58 GMT

You are saying semicolon after "%superq(varcond)" this right?

I did put it still shows same error.

Re: Macro Variable

petlove — Tue, 17 Jul 2018 15:34:14 GMT

Thank you Chris.

In my other program, I am calling this %varcond in %if condition as follow:

%if %varcond(&dsn) %then %do;

proc sort data=sdtmcro.&dsn out=&dsn;
by usubjid ;
run;

%end;

But, I get following error:

ERROR: Required operator not found in expression: %varcond(&dsn)
MLOGIC(VARCOND): %PUT %superq(varcondn)

I expect to run do loop by checking this condition:

%if %varcond %then %do should be equal to %if %varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2) %then %do

When I recall macro in following way, there is no error.

%varcond(LB);

MLOGIC(VARCOND): %PUT %superq(varcond)
%varexist(sdtmcro.LB,LBSTRESC) and %varexist(sdtmcro.LB,LBDRVFL)

However, when I write it in %if condition, I still see this error where "%PUT %superq(varcond)" is blank:

%if %varcond(LB) %then %do;

proc sort data=sdtmcro.&dsn out=&dsn;
by usubjid ;
run;

%end;

LOG:

SYMBOLGEN: Macro variable DSN resolves to LB
ERROR: Required operator not found in expression: %varcond(&dsn)
MLOGIC(VARCOND): %PUT %superq(varcond);

Re: Macro Variable

Tom — Tue, 17 Jul 2018 16:01:43 GMT

Is this the %VARCOND() macro you are trying to call in the middle of a %IF statement?

13         %macro varcond;
14         %let dsn=AE;
15         	data _temp_;
16         			%do i =1 %to %sysfunc(countw(&variables.));
17                			 %let var=%scan(&variables.,&i);
18         				varcond= "%"||"varexist(sdtmcro.&dsn,&var)";
19                			 output;
20         			 %end;
21         			 domain="&dsn";
22         	run;
23         
24         proc sort data=_temp_;
25         by domain ;
26         run;
27         
28         data _temp_;
29         length varcondn $500.;
30         do until(last.domain );
31         set _temp_;
32         by domain ;
33         varcondn=catx(' and ',varcondn,varcond);
34         end;
35         run;
36         
37         proc sql;
38         select varcondn into : varcondn
39         from _temp_;
40         quit;
41         
42         %put &varcondn.;
43         
44         %mend varcond;

It is generating many many SAS statements. You cannot call that macro in the middle of another statement.

If you write

%if %varcond(lb) %then ....

It will generate code into the middle of your %IF statement.

%if data _tmp_; ...

It looks like that macro is intended to set a macro variable named VARCONDN.

So first create the macro variable. Then call the macro. Then test the macro variable.

%let varcondn=0 ;
%varcond;
%if (&varcondn) %then ....

Re: Macro Variable

petlove — Tue, 17 Jul 2018 16:01:29 GMT

Yes. This is the macro I am calling in another program.

What will be the best approach to create macro variable which holds the "string" e.g. "%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)" and it can be recalled in another program in IF statement?

NOTE:

VAR1 and VAR2 can be any variables which are defined in some other macro variable &VARIABLES. This is not constant macro variable, it changes with dataset name.

Re: Macro Variable

Tom — Tue, 17 Jul 2018 16:22:40 GMT

@petlove wrote:

What will be the best approach to create macro variable which holds the "string" e.g. "%varexist(sdtmcro.&dsn,var1) and %varexist(sdtmcro.&dsn,var2)" and it can be recalled in another program in IF statement?

NOTE:

VAR1 and VAR2 can be any variables which are defined in some other macro variable &VARIABLES. This is not constant macro variable, it changes with dataset name.

Here is a macro that you can in a "functional" mode. That is it emits only part of a statement. So you could use it inside an IF, %IF or assignment statement.

%macro varcond(dsn,varlist);
%local i sep ;
%do i=1 %to %sysfunc(countw(&varlist));
  &sep  %varexist(&dsn,%scan(&varlist,&i))
  %let sep=and;
%end;
%mend varcond;

So you might use it this way.

80   options mprint;
81   %let mydataset=SASHELP.CLASS;
82   %let variables=AGE GENDER ;
83   data _null_;
84     if %varcond(&mydataset,&variables) then put "&mydataset has all of the variables: &variables"
84 ! ;
MPRINT(VAREXIST):   3
MPRINT(VARCOND):   and
MPRINT(VAREXIST):   0
85     else put "&mydataset is missing one or more of the variables: &variables";
86   run;

SASHELP.CLASS is missing one or more of the variables: AGE GENDER
NOTE: DATA statement used (Total process time):
      real time           0.26 seconds
      cpu time            0.01 seconds


87
88   %let variables=AGE SEX ;
89   data _null_;
90     if %varcond(&mydataset,&variables) then put "&mydataset has all of the variables: &variables"
90 ! ;
MPRINT(VAREXIST):   3
MPRINT(VARCOND):   and
MPRINT(VAREXIST):   2
91     else put "&mydataset is missing one or more of the variables: &variables";
92   run;

SASHELP.CLASS has all of the variables: AGE SEX
NOTE: DATA statement used (Total process time):
      real time           0.34 seconds
      cpu time            0.00 seconds

Re: Macro Variable

petlove — Tue, 17 Jul 2018 16:37:17 GMT

Thank you so much Tom for your suggestion. The approach you mentioned is working in my program.