topic Re: An unexplained warning with a macro variable. in SAS Programming

An unexplained warning with a macro variable.

Sam28041977 — Wed, 09 May 2018 09:43:05 GMT

Hello,

I don't understand why I had a warning when executing this piece of code:

%do i=1 %to 100;
%put %cmpres(&x%left(%sysevalf(&i.-1)));

WARNING: Apparent symbolic reference X not resolved.

Even though it gives the right result (X0=17)

I get the same warning result with

%put %cmpres(&x%eval(&i.-1));

Thank you for your help

Re: An unexplained warning with a macro variable.

Vish33 — Wed, 09 May 2018 09:41:48 GMT

I think its because of missing '.' .use &x. if not resolved try to see other options if the macro variable "X" is declared outside of macro and you are trying to invoke that within a macro.

Re: An unexplained warning with a macro variable.

RW9 — Wed, 09 May 2018 10:31:22 GMT

You have written in your code: &x. This x is a macro variable, denoted by the use of the ampersand. The error is telling you that there is no macro variable called X in existence. Thus it cannot de-reference the macro variable X and just displays the macro variable name X. In the code you present there is no definition of a macro variable X, so why o you have &x? To be honest, this:

%put %cmpres(&x%left(%sysevalf(&i.-1)));

Looks a bit of a mess anyways, what are you trying to do/achieve?

Re: An unexplained warning with a macro variable.

Astounding — Wed, 09 May 2018 10:48:32 GMT

As @RW9 mentioned, there is no such thing as &x in this program. That's where the message is coming from. If you want to get x0 out of this, you could simplify with:

%put x%eval(&i.-1);

Re: An unexplained warning with a macro variable.

Sam28041977 — Wed, 09 May 2018 11:16:29 GMT

I have X0 (my initial value) and I want to calculate X1,...X100

it is why I need &X0, &X1, ...

X1 depend on X0 and X2 depend on X1, ...

As I mintionned in my email, the code works but I dont understand why given the warning.

What I provided you is just a small part of the code.

the %put is just to reproduce the warning

Re: An unexplained warning with a macro variable.

Astounding — Wed, 09 May 2018 11:25:53 GMT

To get the value of &X0, try:

%put &&x%eval(&i.-1);

Re: An unexplained warning with a macro variable.

RW9 — Wed, 09 May 2018 11:36:46 GMT

So your creating 100 macro variables, macro is not a replacement for Base SAS. If your creating hundreds of data items, then a dataset is where to store that information. If your using more than 2 or 3 macro variables, multiple de-references and %functions, then you should really re-think your problem as I can guarentee that there is a far simpler method of achieving what you want.

Re: An unexplained warning with a macro variable.

Sam28041977 — Wed, 09 May 2018 12:05:32 GMT

I am not creating 100 macro variables.

I am doing robust estimations by iterating until the difference in the estimate i and i-1 is close to 0.

As I get always this without reaching 100 iteration I fixed the max iteration to 100.

Only the final estimate interest me.

Re: An unexplained warning with a macro variable.

Sam28041977 — Wed, 09 May 2018 12:07:14 GMT

I already tested it even I didn't believe why it should work better.

The warning is still present

Re: An unexplained warning with a macro variable.

RW9 — Wed, 09 May 2018 12:23:00 GMT

Well, i am not a statistician, so can't guide as I would like, but checking the documentation, there appears to be quite a few examples in the documentation:

http://support.sas.com/documentation/cdl/en/procstat/67528/HTML/default/viewer.htm#procstat_univariate_details22.htm

Re: An unexplained warning with a macro variable.

Sam28041977 — Wed, 09 May 2018 13:10:26 GMT

Thank you!

I am using a very specific calculus from an ISO guideline.

The problem is not about statistics.

I reformulate my question.

Why this code works (give the right result 17) but produce a warning?

%macro mac();
%let i=1;
%let x0=17;
%put %cmpres(&x%eval(&i.-1));
%mend mac;
%mac();

Re: An unexplained warning with a macro variable.

Astounding — Wed, 09 May 2018 13:20:43 GMT

Probably lost in the confusion of so many messages ...

Your code refers to &X. That means the macro variable X. There is no macro variable X, hence the message.

Re: An unexplained warning with a macro variable.

RW9 — Wed, 09 May 2018 13:36:17 GMT

Well, its a real pain, and a very good example of why not use macro language for data processing. However this example does work:

%macro mac();
      %let i=1;
      %let x0=17;
      %let x=x%eval(&i.-1);
     %put &&&x.;
%mend mac;
%mac();

You see how quickly that gets all messy, do it in a datastep, much nicer simpler code.

Re: An unexplained warning with a macro variable.

Tom — Wed, 09 May 2018 15:24:59 GMT

@Sam28041977 wrote:

Thank you!

I am using a very specific calculus from an ISO guideline.

The problem is not about statistics.

I reformulate my question.

Why this code works (give the right result 17) but produce a warning?

%macro mac();
%let i=1;
%let x0=17;
%put %cmpres(&x%eval(&i.-1));
%mend mac;
%mac();

Why are you calling the %CMPRES() macro? What do you want to remove?

To get the macro processor to re-evaluate a macro generated token use multiple &. When it sees two & it converts them to one and sets flag that it needs to re-process the result to resolve more macro variable references. Adding in the %EVAL() causes it to treat the string as multiple tokens instead of one.

I find it is easier to either generate the new number into another macro variable. Or generate the macro variable name into another macro variable and use that to find the value.

Play with this example.

%let x1=One ;
%let x2=Two ;
%let one=Value of One ;
%let two=Value of Two ;

%let i=1 ;
%put &&x&i ;
%put &&&&&&x&i ;

%put &&x%eval(&i+1);
%put &&&&&&x%eval(&i+1) ;

%let j=%eval(&i+1) ;
%put &&x&j ;
%put &&&&&&x&j ;

%let name=x&i;
%put One=&name Three=&&&name Seven=&&&&&&&name  ;

%let name=x%eval(&i+1);
%put One=&name Three=&&&name Seven=&&&&&&&name  ;

Re: An unexplained warning with a macro variable.

ballardw — Wed, 09 May 2018 15:52:14 GMT

@Sam28041977 wrote:

I have X0 (my initial value) and I want to calculate X1,...X100

it is why I need &X0, &X1, ...

X1 depend on X0 and X2 depend on X1, ...

As I mintionned in my email, the code works but I dont understand why given the warning.

What I provided you is just a small part of the code.

the %put is just to reproduce the warning

Show an actual example of what your are attempting with some values and the desired result.

I suspect that array processing might work an possibly no macro needed for that part.

Re: An unexplained warning with a macro variable.

Sam28041977 — Sun, 13 May 2018 08:38:46 GMT

hello,

the algorithme that is described bellow. my full macro is bellow also. the input of the macro is a 2 columns datasets (lab and result). this algorithm detect labs with deviations.

%macro prof(var=,data=);
data &data.;
set anadat.&data.;
if &var ne .;
run;
proc means data=&data.;
	where &var. ne .;
	var &var.;
	output out=a median=x;
run;

PROC SQL;
	SELECT x INTO:X0 FROM a;
QUIT;

PROC SQL;
	CREATE TABLE &var. AS SELECT Lab, &var. as &var.0, (ABS(&var.-&x0.)) AS DIFF0 FROM &data.;
QUIT;

proc means data=&var. median;
	var Diff0;
	output out=b median=s;
run;

PROC SQL;
	SELECT (S*1.483) INTO:S0 FROM B;
	SELECT (S*1.483*1.5) INTO:sigma0 FROM B;
QUIT;
DATA &var.S0;
ITER=0;X=ROUND(&X0.,.01);S=ROUND(&S0.,.01); Sigma=ROUND(&sigma0.,.01); 
X_=&X0;S_=&S0; Sigma_=&sigma0; OUTPUT;
RUN;

DATA &VAR.;
SET &VAR.;
DROP DIFF0;
RUN;

%do i=1 %to 100;
%put %cmpres(&&&&x%eval(&i.-1));
data &var.;
	SET &var.;
	if &var.0 ne . and &var.0<(%cmpres(&x%eval(&i.-1))-%cmpres(&sigma%eval(&i.-1))) then &var.&i.=(%cmpres(&x%eval(&i.-1))-%cmpres(&sigma%eval(&i.-1)));
	else if &var.0 ne . and &var.0>(%cmpres(&x%eval(&i.-1))+%cmpres(&sigma%eval(&i.-1))) then &var.&i.=(%cmpres(&x%eval(&i.-1))+%cmpres(&sigma%eval(&i.-1)));
	else if &var.0 ne . then &var.&i.=&var.0;
run;

PROC SQL;
	SELECT mean(&var.&i.) INTO: x&i. FROM &var.;
	SELECT (1.134*std(&var.&i.)) INTO: s&i. FROM &var.;
	SELECT (1.5*1.134*std(&var.&i.)) INTO: sigma&i. FROM &var.;
QUIT;
DATA &var.S&i.;
ITER=&i.;X=ROUND(&&X&i.,.01);S=ROUND(&&S&i.,.01); Sigma=ROUND(&&sigma&i.,.01);
X_=&&X&i.;S_=&&S&i.; Sigma_=&&sigma&i.;OUTPUT;
RUN;
%if &i.>1 %then %Do;
	DATA _NULL_;
		CALL symput ('x_',round(&&x&i.,.01));
		CALL symput ('x__',round(%cmpres(&x%eval(&i.-1)),.01));
		CALL symput ('x___',round(%cmpres(&x%eval(&i.-2)),.01));
		CALL symput ('s_',round(&&s&i.,.01));
		CALL symput ('s__',round(%cmpres(&s%eval(&i.-1)),.01));
		CALL symput ('s___',round(%cmpres(&s%eval(&i.-2)),.01));
	RUN;

	%if (&x_. eq &x__.) and (&s_. eq &s__.) and (&x_. eq &x___.) and (&s_. eq &s___.)%then %do;
	DATA &var._;
		SET &var.;
		FORMAT Z 5.2 Z_ $10. BIAS 5.2 BIAS_ $10. X S 5.2;
		X=&&x&i.;
		S=&&s&i.;
		IF &var.0 NE . THEN Z=(&var.0-&&x&i.)/&&s&i.;
		IF &var.0 NE . THEN BIAS=(&var.0-&&x&i.);
		if Z<-3 or z>3 then DO;
			IF Z NE . THEN Z_=compbl(put(Z,5.2)!!"A");
			IF BIAS NE . THEN BIAS_=compbl(put(BIAS,5.2)!!"A");
		end;
		else if Z<-2 or z>2 then DO;
			IF Z NE . THEN Z_=compbl(put(Z,5.2)!!"W");
			IF BIAS NE . THEN BIAS_=compbl(put(BIAS,5.2)!!"W");
		end;
		else DO;
			Z_=put(Z,5.2);
			BIAS_=put(BIAS,5.2);
		end;
		label Lab="Lab" X="Assigned value (Robust Estimate)" S="Standard Deviation (Robust Estimate)"
			  BIAS="Estimate of Lab Bias" BIAS_="Estimate of Lab Bias (With Flag)"
			  Z="Z Score" Z_="Z Score (With Flag)";
		KEEP Lab &VAR.0 X S BIAS BIAS_ Z Z_;
	run;
	proc sql;
	create table anadat.&var. as select Lab, &var.0, X, S, BIAS, BIAS_, Z, Z_
	from &var._;
	quit;
 
	DATA &var.S;
	SET &var.S0 %do g=1 %to &i.; &var.s&g. %end;;
	RUN;
	%goto exit;
	%end;
%end;
%end;
%exit:
/*proc datasets library=work;
	delete &var.S: S:;
quit; */
%mend prof;
%prof(var=WR10_S,data=%str(DATA));

Re: An unexplained warning with a macro variable.

Astounding — Sun, 13 May 2018 17:52:18 GMT

So in some cases, you fixed the problem, changing & to &&. (In one place, you even used &&&& which doesn't hurt anything, since &&&& resolves to && anyway.)

In a bunch of other places you left a single & where you require &&. So you are still getting the error message, but macro language is not that helpful in describing where the error occurs. Do you need help in understanding when to change & to && so that the macro expressions resolve correctly?

Re: An unexplained warning with a macro variable.

Sam28041977 — Mon, 14 May 2018 08:15:40 GMT

hello Astounding,

adding & or && or &&& don't resolved the problem.

But what I wanted to explain from the begining is that I don't understand the warning because the macros variable resolve correctly whatever the number of &.

I provided a small macro that show that the result is correct but I still have a warning.

krs

Re: An unexplained warning with a macro variable.

Tom — Mon, 14 May 2018 10:53:03 GMT

@Sam28041977 wrote:

hello Astounding,

adding & or && or &&& don't resolved the problem.

But what I wanted to explain from the begining is that I don't understand the warning because the macros variable resolve correctly whatever the number of &.

I provided a small macro that show that the result is correct but I still have a warning.

krs

When the macro processor sees a macro variable reference it replaces the reference with the value of the macro variable. But when you reference a macro variable that doesn't exist the macro processor generates a warning and then DOES NOTHING with the incoming text.

Because you are then using the resulting text in a place where the macro processor will re-process the resulting string is why it ultimately generates the desired result. The second time it processes it the macro processor sees a valid macro variable reference.

You can see the same result with code like this.

%let x2=TWO;

%put &x%eval(1+1);
%Put %unquote(&x%eval(1+1));