topic Re: single quote in macro variable in SAS Programming

single quote in macro variable

luu — Mon, 09 Apr 2018 19:06:17 GMT

There is a single quote in macro variable test. How could i assign macro variable test to test1 in data set test? Thanks!

%let test=%str(antidepressant -can't remember name);
data test;
test1=&test;
run;

Re: single quote in macro variable

Reeza — Mon, 09 Apr 2018 19:17:17 GMT

Try the following:
test1 = "&test";

You need quotes anyways, to store it as a character variable, otherwise you're saying:

test1=antidpressant;

Which is looking for a variable called antidepressant, not the value of antidepressant.

Re: single quote in macro variable

Astounding — Mon, 09 Apr 2018 19:18:08 GMT

You would use the same method whether or not there is a single quote:

data test;
test1="&test";
run;

The only time you run into a problem is when &TEST contains doublequotes.

Re: single quote in macro variable

luu — Mon, 09 Apr 2018 19:27:24 GMT

Thank you for your reply. I write it as test1="&test" but still has error. It seems the single quote in macro variable test cannot be resolved well.

ERROR 22-322: Syntax error, expecting one of the following: !, !!, &, *, **, +, -, /, <, <=, <>,
=, >, ><, >=, AND, EQ, GE, GT, LE, LT, MAX, MIN, NE, NG, NL, OR, ^=, |, ||, ~=.

ERROR 388-185: Expecting an arithmetic operator.

Re: single quote in macro variable

luu — Mon, 09 Apr 2018 19:27:42 GMT

Thank you for your reply. I write it as test1="&test" but still has error. It seems the single quote in macro variable test cannot be resolved well.

ERROR 22-322: Syntax error, expecting one of the following: !, !!, &, *, **, +, -, /, <, <=, <>,
=, >, ><, >=, AND, EQ, GE, GT, LE, LT, MAX, MIN, NE, NG, NL, OR, ^=, |, ||, ~=.

ERROR 388-185: Expecting an arithmetic operator.

Re: single quote in macro variable

novinosrin — Mon, 09 Apr 2018 19:29:31 GMT

%let test=%bquote(antidepressant -can't remember name);
%put &test;
data test;
test1="&test";
run;

love the %bquote

Re: single quote in macro variable

novinosrin — Mon, 09 Apr 2018 19:31:08 GMT

or wanna keep and play with %str then precede the unmatched quote with % like the following:

%let test=%str(antidepressant -can%'t remember name);
%put &test;
data test;
test1="&test";
run;

Re: single quote in macro variable

Astounding — Mon, 09 Apr 2018 19:39:07 GMT

As indicated, getting quotes into and out of a macro variable can be tricky. I would go with %STR in this case. For experimentation and learning, here's a program you can run and try to explain:

data _null_;

call symputx('p', "This won't work");

run;

%put &p;

DON'T do this in the middle of an interactive session. (Unless you figure out how the program works, you would need to shut down the session and start over.) Use a background job.

Re: single quote in macro variable

luu — Mon, 09 Apr 2018 19:45:40 GMT

Thank you very much! That works! But do you know how to only change test1="&test" writing instead of change the define of &test?

Because i simplied the code for the question. In my original code the &test variable is the value of a column of a dataset not the variable using %let defined.

Re: single quote in macro variable

novinosrin — Mon, 09 Apr 2018 20:03:05 GMT

@luuwrote:
In my original code the &test variable is the value of a column of a dataset not the variable using %let defined.

In that case you don't need the double quotes wrapper

PS we do not know your data, so we can only assume and guess. HTH

So give me a sample of the data please

Re: single quote in macro variable

Astounding — Mon, 09 Apr 2018 19:51:18 GMT

In a DATA step, I would try:

test1 = "%superq(test)";

Re: single quote in macro variable

ballardw — Mon, 09 Apr 2018 20:06:04 GMT

Assuming that at some point in this session you attempted to execute:

%let test = somestr'ng;

Everything from that point on is likely suspect as you did not complete the assignment to test. The first single quote "ate" the semicolon until the next single quote appeared in your session.

So without a posting from the log of submitted code AND the error message and preferably posted into a code box to prevent the forum message windows from reformatting text it does not help very much to post random snippets from the log.

If you are using the enhanced editor and have reasonable code highlighting settings the text should give a clue something is happening.

%let test = somestr'ng'; 
%let somethingelse=blah;


%let test = somestr'ng; 
%let somethingelse=blah;

Notice that even the minimal highlighting in the code box shows the string enclosed with quotes in the first ling as a different color but in the third line with the single quote there is no highlight color. Indicates a quote issue.

Re: single quote in macro variable

Reeza — Mon, 09 Apr 2018 20:07:22 GMT

If the column name has a single quote in it, you need to use literals, use double quotes and the n at the end.

test = "&test"n;

Re: single quote in macro variable

luu — Mon, 09 Apr 2018 20:25:58 GMT

Thank you for your great help!

Part of my data is like this, there is a variable named "medicine_name"

medicine_name

levothyroxin 100mgcg

antidepressant -can't remember name

Simvastatin Tabs

gabapentin 300mg

I put them into a list of macro vairables:

proc sql noprint;

select medicine_name into : test1-:test99999 from xxx;

quit;

And then assign macro variable into a dataset variable:

data result;

med="&test2";

run;

Because &test2 is "antidepressant -can't remember name", at this point, i get the error.

Re: single quote in macro variable

novinosrin — Mon, 09 Apr 2018 20:35:26 GMT

Your code seems to work fine when i tested it:

data xxx;

input  medicine_name $50.;
datalines;
levothyroxin 100mgcg
antidepressant -can't remember name
Simvastatin Tabs
gabapentin 300mg
;

proc sql noprint;

        select medicine_name into : test1-:test99999 from xxx;

quit;

 

/*And then assign macro variable into a dataset variable:*/

data result;

med="&test2";

run;

Here is the log:

228 data xxx;
229
230 input medicine_name $50.;
231 datalines;

NOTE: The data set WORK.XXX has 4 observations and 1 variables.
NOTE: DATA statement used (Total process time):
real time 0.01 seconds
cpu time 0.01 seconds

236 ;
237
238 proc sql noprint;
239
240 select medicine_name into : test1-:test99999 from xxx;
241
242 quit;
NOTE: PROCEDURE SQL used (Total process time):
real time 0.00 seconds
cpu time 0.01 seconds

243
244
245
246 /*And then assign macro variable into a dataset variable:*/
247
248 data result;
249
250 med="&test2";
251
252 run;

NOTE: The data set WORK.RESULT has 1 observations and 1 variables.
NOTE: DATA statement used (Total process time):
real time 0.00 seconds
cpu time 0.01 seconds

Re: single quote in macro variable

novinosrin — Mon, 09 Apr 2018 21:17:32 GMT

@luu Ok I think you have a point here as my successive tests kinda gave me crazy log messages. Why bother. Just immediately quote it before the datastep like this:

data xxx;

input  medicine_name $50.;
datalines;
levothyroxin 100mgcg
antidepressant -can't remember name
Simvastatin Tabs
gabapentin 300mg
;
%macro luu;

proc sql noprint;

        select medicine_name into : test1-:test99999 from xxx;

quit;

  %do i=1 %to &sqlobs;
  %let test&i=%bquote(&&test&i);
  %end;


/*And then assign macro variable into a dataset variable:*/

data result;

med="&test2";

run;

%mend ulu;

%luu

This is a safe bet. HTH

Re: single quote in macro variable

luu — Mon, 09 Apr 2018 22:32:20 GMT

You are right, this program can run through. I notice there are some other places I used &test2 I have modified it. Thank you very much for your great help!