topic Panel Data: Identify the first occurrence of an event within a by group in SAS Programming

Panel Data: Identify the first occurrence of an event within a by group

DB_ECON — Mon, 28 Feb 2011 19:22:44 GMT

I have a panel data with to identifiers: ID and Time. The dataset contains the following variables: ID, Time and V1. I want to create a fourth variable Flag which will identify the first date where V1 > 0 for each ID. For eg: The third observations identifies the third month as the first occurrence of a positive V1 for ID = 1. Again the seventh observation identifies the second month as the first occurrence of a positive V1 for ID = 2 . Thanks in advance.

ID Time V1 Flag
1 , 1, 0, 0
1 , 2, 0, 0
1 , 3, 7.5, 3
1 , 4, 6, 0
1 , 5, 0, 0
2 , 1, 0, 0
2 , 2, 9, 2
2 , 3, 9, 0
2 , 4, 0, 0
2 , 5, 2.5, 0

Re: Panel Data: Identify the first occurrence of an event within a by group

Reeza — Mon, 28 Feb 2011 23:33:01 GMT

Use retain with by groups and a found flag to indicate if the variable has already been set.
[pre]
data want;
set have;
by id;

retain found;

if first.id then found=0;

flag=0;

if v1 ne 0 and found=0 then do;
flag=time;
found=1;
end;

drop found;
run;
[/pre]

Re: Panel Data: Identify the first occurrence of an event within a by group

Ksharp — Tue, 01 Mar 2011 02:26:54 GMT

Hi.
If your data look like you post (e.g have been sorted).

[pre]

data temp;
infile datalines dlm=' ,';
input ID Time V1;
cards;
1 , 1, 0
1 , 2, 0
1 , 3, 7.5
1 , 4, 6
1 , 5, 0
2 , 1, 0
2 , 2, 9
2 , 3, 9
2 , 4, 0
2 , 5, 2.5
;
run;
data temp(drop=_id);
set temp;
retain _id .;
if id ne _id and v1 gt 0 then do;
_id=id;
flag=time;
end;
else flag=0;
run;
[/pre]

Ksharp

Message was edited by: Ksharp Message was edited by: Ksharp

Re: Panel Data: Identify the first occurrence of an event within a by group

DB_ECON — Wed, 02 Mar 2011 16:43:22 GMT

Thanks a lot Reeza.....This works great!!

Re: Panel Data: Identify the first occurrence of an event within a by group

DB_ECON — Wed, 02 Mar 2011 16:44:43 GMT

Thanks a lot to Ksharp as well.....This code also does the job....
Thanks Guys!!!