topic Re: Drop lowercase variable in SAS Programming

Drop lowercase variable

Jackwangliang — Wed, 28 Mar 2018 03:49:27 GMT

Hi all,

How can I drop lowercase variable? For example,

original variable set:

CHF VALVVE PULMCIRC OBESE oCHF oVALVVE oPULMCIRC oOBESE

target variable set:

CHF VALVVE PULMCIRC OBESE

Best,

JackLiang

Re: Drop lowercase variable

Shmuel — Wed, 28 Mar 2018 04:33:27 GMT

You may prefer use KEEP instead DROP.

Re: Drop lowercase variable

ChrisNZ — Wed, 28 Mar 2018 04:40:30 GMT

Like this?

data HAVE;
  retain CHF VALVVE PULMCIRC OBESE oCHF oVALVVE oPULMCIRC oOBESE 1;
run;
proc contents data=HAVE noprint out=CONT;
run;
data _null_;
  set CONT end=LASTOBS;
  if _N_ = 1                  then call execute('data WANT; set HAVE; drop ');
  if prxmatch('/[a-z]/',NAME) then call execute(NAME);
  if LASTOBS                  then call execute(';run;');
run;

Re: Drop lowercase variable

novinosrin — Wed, 28 Mar 2018 04:43:16 GMT

data have;
length CHF VALVVE PULMCIRC OBESE oCHF oVALVVE oPULMCIRC oOBESE 8;

run;
proc contents data=HAVE noprint out=_have;
quit;
proc sql;
select 	name into :drop separated by ' '
from _have 
where  anylower(name)>0;
QUIT;

data want;
set have;
drop &drop;
run;

Re: Drop lowercase variable

Patrick — Wed, 28 Mar 2018 11:48:21 GMT

@Jackwangliang

Or if the variables you want to drop always start with a lowercase o then here a coding variant to @novinosrin

data have;
  length CHF VALVVE PULMCIRC OBESE oCHF oVALVVE oPULMCIRC oOBESE 8;
  stop;
run;

proc sql noprint;
  select  name into :drop separated by ' '
    from dictionary.columns
    where libname='WORK' and memname='HAVE' and name like 'o%'
    ;
quit; 

data want;
  set have;
  drop &drop;
run;

Or this way in case your table is in a data base or/and you want to conserve indices and the like

data have;
  length CHF VALVVE PULMCIRC OBESE oCHF oVALVVE oPULMCIRC oOBESE 8;
  stop;
run;

%let drop=;
proc sql noprint feedback;
  select  name into :drop separated by ','
    from dictionary.columns
    where libname='WORK' and memname='HAVE' and name like 'o%'
    ;
  alter table have
    drop &drop
  ;
quit;

Re: Drop lowercase variable

Jackwangliang — Thu, 29 Mar 2018 00:08:12 GMT

Thank you.

Re: Drop lowercase variable

Jackwangliang — Thu, 29 Mar 2018 00:08:20 GMT

Thanks you.

Re: Drop lowercase variable

Jackwangliang — Thu, 29 Mar 2018 00:08:44 GMT

Thank you