topic Re: Flag words containing or made of numeric in SAS Programming

Flag words containing or made of numeric

brulard — Tue, 27 Mar 2018 13:00:30 GMT

hi,

Can someone suggest a code /function to scan string and return num value when:

Where any character within string where delimetor is 1 or more space, begin scanning: If contains or is made up of numeric, flag 1. This is to scan string related to addresses.

Examples for variable Address1

(i) 145 SAINT-GEORGES #1107

(ii) 12 MIDDLEPORT CRESEN

(iii) 2040 ALGONQUIN RD UNIT114

(iv) BUREAU 106

Output

(i) 2 [flags '145' as 1, and flags '#1107' as 1]

(ii) 1 [flags '12' as 1]

(iii) 2

(iv) 1

thanks... I'm gonna review Perl and see what i can get.

Re: Flag words containing or made of numeric

PaigeMiller — Tue, 27 Mar 2018 13:18:13 GMT

The ANYDIGIT function will do what you want

Re: Flag words containing or made of numeric

Ksharp — Tue, 27 Mar 2018 13:19:49 GMT

OK. Assuming I understood what you mean.

data have;
input;
have=_infile_;
pid=prxparse('/\d+/');
s=1;e=length(_infile_);
n=0;
call prxnext(pid,s,e,_infile_,p,l);
do while(p>0);
 n+1;
 call prxnext(pid,s,e,_infile_,p,l);
end;
keep have n;
cards;
(i)  145 SAINT-GEORGES #1107
(ii) 12 MIDDLEPORT CRESEN
(iii) 2040 ALGONQUIN RD UNIT114
(iv) BUREAU 106
;
run;

proc print noobs;run;

Re: Flag words containing or made of numeric

brulard — Tue, 27 Mar 2018 13:23:07 GMT

hello Mr Ksharp, a quick thank you for your tip! Also, you and others like R9, Astounding, etc.. are a real inspiration to study and practice SAS & coding!

Re: Flag words containing or made of numeric

Ksharp — Wed, 28 Mar 2018 12:11:29 GMT

If you consider non-prx way, the COUNTW() is the best choice .

data have;
input;
have=_infile_;
n=countw(have,,'kd');
keep have n;
cards;
(i)  145 SAINT-GEORGES #1107
(ii) 12 MIDDLEPORT CRESEN
(iii) 2040 ALGONQUIN RD UNIT114
(iv) BUREAU 106
;
run;

proc print noobs;run;

Re: Flag words containing or made of numeric

brulard — Wed, 28 Mar 2018 15:26:47 GMT

hi Ksharp, thanks this works too